blob: 0a1d557dd9352a96f3b6ce14839a9cffa0858f61 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
{ stdenv, fetchurl, openssl, nettle, expat, libevent }:
stdenv.mkDerivation rec {
name = "unbound-${version}";
version = "1.6.1";
src = fetchurl {
url = "http://unbound.net/downloads/${name}.tar.gz";
sha256 = "000lylg5qgriaxh6k78l2inb905qshx01kxgmqj89zn08gvn7ps2";
};
outputs = [ "out" "lib" "man" ]; # "dev" would only split ~20 kB
buildInputs = [ openssl nettle expat libevent ];
configureFlags = [
"--with-ssl=${openssl.dev}"
"--with-libexpat=${expat.dev}"
"--with-libevent=${libevent.dev}"
"--localstatedir=/var"
"--sysconfdir=/etc"
"--sbindir=\${out}/bin"
"--enable-pie"
"--enable-relro-now"
];
installFlags = [ "configfile=\${out}/etc/unbound/unbound.conf" ];
preFixup = stdenv.lib.optionalString stdenv.isLinux
# Build libunbound again, but only against nettle instead of openssl.
# This avoids gnutls.out -> unbound.lib -> openssl.out.
# There was some problem with this on Darwin; let's not complicate non-Linux.
''
configureFlags="$configureFlags --with-nettle=${nettle.dev} --with-libunbound-only"
configurePhase
buildPhase
installPhase
''
# get rid of runtime dependencies on $dev outputs
+ ''substituteInPlace "$lib/lib/libunbound.la" ''
+ stdenv.lib.concatMapStrings
(pkg: " --replace '-L${pkg.dev}/lib' '-L${pkg.out}/lib' ")
buildInputs;
meta = with stdenv.lib; {
description = "Validating, recursive, and caching DNS resolver";
license = licenses.bsd3;
homepage = https://www.unbound.net;
maintainers = with maintainers; [ ehmry fpletz ];
platforms = stdenv.lib.platforms.unix;
};
}
|