pkgs/os-specific/linux/tiptop/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

{ stdenv, fetchurl, fetchpatch, libxml2, ncurses, bison, flex }:

stdenv.mkDerivation rec {
  name = "tiptop-${version}";
  version = "2.3.1";

  src = fetchurl {
    url = "${meta.homepage}/releases/${name}.tar.gz";
    sha256 = "10j1138y3cj3hsmfz4w0bmk90523b0prqwi9nhb4z8xvjnf49i2i";
  };

  patches = [(fetchpatch {
    name = "reproducibility.patch";
    url = "http://anonscm.debian.org/cgit/collab-maint/tiptop.git/plain/debian/"
      + "patches/0001-fix-reproducibility-of-build-process.patch?id=c777d0d5803";
    sha256 = "116l7n3nl9lj691i7j8x0d0za1i6zpqgghw5d70qfpb17c04cblp";
  })];

  postPatch = ''
    substituteInPlace ./configure --replace -lcurses -lncurses
  '';

  nativeBuildInputs = [ flex bison ];
  buildInputs = [ libxml2 ncurses ];

  NIX_CFLAGS_COMPILE = [ "-I${libxml2.dev}/include/libxml2" ];

  meta = with stdenv.lib; {
    description = "Performance monitoring tool for Linux";
    homepage = http://tiptop.gforge.inria.fr;
    license = licenses.gpl2;
    platforms = platforms.linux;
    maintainers = [ maintainers.vcunat ];
  };
}