pkgs/development/python-modules/tornado/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

{ lib
, python
, buildPythonPackage
, fetchPypi
, backports_abc
, backports_ssl_match_hostname
, certifi
, singledispatch
, pythonOlder
, futures
, version ? "5.1"
}:

let
  versionMap = {
    "4.5.3" = {
      sha256 = "02jzd23l4r6fswmwxaica9ldlyc2p6q8dk6dyff7j58fmdzf853d";
    };
    "5.1" = {
      sha256 = "4f66a2172cb947387193ca4c2c3e19131f1c70fa8be470ddbbd9317fd0801582";
    };
  };
in

with versionMap.${version};

buildPythonPackage rec {
  pname = "tornado";
  inherit version;

  propagatedBuildInputs = [ backports_abc  certifi singledispatch ]
    ++ lib.optional (pythonOlder "3.5") backports_ssl_match_hostname
    ++ lib.optional (pythonOlder "3.2") futures;

  # We specify the name of the test files to prevent
  # https://github.com/NixOS/nixpkgs/issues/14634
  checkPhase = ''
    ${python.interpreter} -m unittest discover *_test.py
  '';

  src = fetchPypi {
    inherit pname sha256 version;
  };

  meta = {
    description = "A web framework and asynchronous networking library";
    homepage = http://www.tornadoweb.org/;
    license = lib.licenses.asl20;
  };
}