blob: 5e7e921710f0a9017b762edb0995810d2d006cc5 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
{ stdenv, fetchurl, makeDesktopItem
, xlibs, gtkLibs, gnome
, dbus, dbus_glib, fontconfig, gcc, patchelf
}:
# this package contains the daemon version of dropbox
# it's unfortunately closed source
#
# note: the resulting program has to be invoced as
# 'dropbox' because the internal python engine takes
# uses the name of the program as starting point.
#
# todo: dropbox is shipped with some copies of libraries.
# replace these libraries with the appropriate ones in
# nixpkgs.
# note: there is a i686 version available as well
assert stdenv.system == "x86_64-linux";
let
version = "1.2.52";
sha256 = "72aeaf00727da9f3fe39386dcf883bb303de928ba43c738fcc5bb62b93eca252";
# relative location where the dropbox libraries are stored
sharedir = "share/dropbox";
# Libraries referenced by dropbox binary.
# Be aware that future versions of the dropbox binary may refer
# to different versions than are currently in these packages.
ldpath = with xlibs; with gtkLibs; with gnome;
stdenv.lib.makeSearchPath "lib" [
libSM libX11 libXext libXcomposite libXcursor libXdamage
libXfixes libXi libXinerama libXrandr libXrender
atk dbus dbus_glib glib fontconfig gcc gdk_pixbuf
gtk pango
];
desktopItem = makeDesktopItem {
name = "dropbox";
exec = "dropbox";
comment = "Online directories";
desktopName = "Dropbox";
genericName = "Online storage";
categories = "Application;Internet;";
};
in stdenv.mkDerivation {
name = "dropbox-${version}-bin";
src = fetchurl {
name = "dropbox-${version}.tar.gz";
url = "http://www.dropbox.com/download?plat=lnx.x86_64";
inherit sha256;
};
sourceRoot = ".";
patchPhase = ''
rm -f .dropbox-dist/dropboxd
'';
installPhase = ''
ensureDir "$out/${sharedir}"
cp -r .dropbox-dist/* "$out/${sharedir}/"
ensureDir "$out/bin"
ln -s "$out/${sharedir}/dropbox" "$out/bin/dropbox"
patchelf --set-interpreter ${stdenv.glibc}/lib/ld-linux-x86-64.so.2 \
"$out/${sharedir}/dropbox"
RPATH=${ldpath}:${gcc.gcc}/lib64:$out/${sharedir}
echo "updating rpaths to: $RPATH"
find "$out/${sharedir}" -type f -a -perm +0100 \
-print -exec patchelf --force-rpath --set-rpath "$RPATH" {} \;
ensureDir "$out/share/applications"
cp ${desktopItem}/share/applications/* $out/share/applications
'';
buildInputs = [ patchelf ];
meta = {
description = "Online stored folders (daemon version)";
homepage = http://www.dropbox.com;
};
}
|