nixos/modules/services/monitoring/prometheus/nginx-exporter.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

{ config, pkgs, lib, ... }:

with lib;

let
  cfg = config.services.prometheus.nginxExporter;
in {
  options = {
    services.prometheus.nginxExporter = {
      enable = mkEnableOption "prometheus nginx exporter";

      port = mkOption {
        type = types.int;
        default = 9113;
        description = ''
          Port to listen on.
        '';
      };

      listenAddress = mkOption {
        type = types.string;
        default = "0.0.0.0";
        description = ''
          Address to listen on.
        '';
      };

      scrapeUri = mkOption {
        type = types.string;
        default = "http://localhost/nginx_status";
        description = ''
          Address to access the nginx status page.
          Can be enabled with services.nginx.statusPage = true.
        '';
      };
    };
  };

  config = mkIf cfg.enable {
    networking.firewall.allowedTCPPorts = [ cfg.port ];

    systemd.services.prometheus-nginx-exporter = {
      wantedBy = [ "multi-user.target" ];
      after = [ "network.target" "nginx.service" ];
      script = ''
        ${pkgs.prometheus-nginx-exporter.bin}/bin/nginx_exporter \
          -telemetry.address ${cfg.listenAddress}:${toString cfg.port} \
          -nginx.scrape_uri ${cfg.scrapeUri}
      '';
      serviceConfig = {
        User = "nobody";
        Restart  = "always";
        PrivateTmp = true;
        WorkingDirectory = /tmp;
      };
    };
  };
}