{ stdenv, lib, fetchFromGitHub, makeWrapper
, meson, ninja, pkg-config, wayland, scdoc
, libxkbcommon, pcre, json_c, libevdev, pango, cairo, libinput, librsvg
, wlroots, wayland-protocols

, gdkPixbufSupport ? true, gdk-pixbuf
, xwaylandSupport ? !(lib.elem "-Dxwayland=disabled" (wlroots.mesonFlags or []))
}:

stdenv.mkDerivation rec {
  pname = "sway-unwrapped";
  version = "1.5.1";

  src = fetchFromGitHub {
    owner = "swaywm";
    repo = "sway";
    rev = version;
    sha256 = "1xsa3h8zhf29p0mi90baxpr76jkd9pd1gr97ky8cnjbcs4isj9j0";
  };

  patches = [
    ./sway-config-no-nix-store-references.patch
    ./load-configuration-from-etc.patch
  ];

  nativeBuildInputs = [
    meson ninja pkg-config wayland scdoc
  ];

  buildInputs = [
    wayland libxkbcommon pcre json_c libevdev pango cairo libinput librsvg
    wlroots wayland-protocols
  ] ++ lib.optional gdkPixbufSupport gdk-pixbuf;

  mesonFlags = [ "-Ddefault-wallpaper=false" ]
    ++ lib.optional gdkPixbufSupport "-Dgdk-pixbuf=enabled"
    ++ lib.optional xwaylandSupport "-Dxwayland=enabled";

  meta = with lib; {
    description = "An i3-compatible tiling Wayland compositor";
    longDescription = ''
      Sway is a tiling Wayland compositor and a drop-in replacement for the i3
      window manager for X11. It works with your existing i3 configuration and
      supports most of i3's features, plus a few extras.
      Sway allows you to arrange your application windows logically, rather
      than spatially. Windows are arranged into a grid by default which
      maximizes the efficiency of your screen and can be quickly manipulated
      using only the keyboard.
    '';
    homepage    = "https://swaywm.org";
    changelog   = "https://github.com/swaywm/sway/releases/tag/${version}";
    license     = licenses.mit;
    platforms   = platforms.linux;
    maintainers = with maintainers; [ primeos synthetica ma27 ];
  };
}