Overlays
This chapter describes how to extend and change Nixpkgs packages using
overlays. Overlays are used to add layers in the fix-point used by Nixpkgs
to compose the set of all packages.
Nixpkgs can be configured with a list of overlays, which are
applied in order. This means that the order of the overlays can be significant
if multiple layers override the same package.
Installing overlays
The list of overlays is determined as follows:
First, if an overlays argument to the nixpkgs function itself is given,
then that is used. This can be passed explicitly when importing nipxkgs, for example
import <nixpkgs> { overlays = [ overlay1 overlay2 ] }.
On a NixOS system the value of the nixpkgs.overlays option, if present,
is passed to the system Nixpkgs in this way. Note that this does not affect the overlays for
non-NixOS operations (e.g. nix-env), which are looked up independently.
Otherwise, if the Nix path entry <nixpkgs-overlays> exists and is a
directory, then the result is the set of overlays found in that directory, ordered lexicographically.
See the section on NIX_PATH in the Nix manual for more details on how to
set a value for <nixpkgs-overlays>.
Otherwise, if ~/.config/nixpkgs/overlays/ exists and is a directory, then
the result is the set of overlays found in that directory, ordered lexicographically.
For the second and third options, overlays are extracted from the given directory as files,
directories containing a default.nix, or symlinks to one of those.
The last option provides a convenient way to install an overlay from a repository,
by cloning the overlay's repository and adding a symbolic link to it in
~/.config/nixpkgs/overlays/.
Defining overlays
Overlays are Nix functions which accept two arguments,
conventionally called self and super,
and return a set of packages. For example, the following is a valid overlay.
self: super:
{
boost = super.boost.override {
python = self.python3;
};
rr = super.callPackage ./pkgs/rr {
stdenv = self.stdenv_32bit;
};
}
The first argument (self) corresponds to the final package
set. You should use this set for the dependencies of all packages specified in your
overlay. For example, all the dependencies of rr in the example above come
from self, as well as the overridden dependencies used in the
boost override.
The second argument (super)
corresponds to the result of the evaluation of the previous stages of
Nixpkgs. It does not contain any of the packages added by the current
overlay, nor any of the following overlays. This set should be used either
to refer to packages you wish to override, or to access functions defined
in Nixpkgs. For example, the original recipe of boost
in the above example, comes from super, as well as the
callPackage function.
The value returned by this function should be a set similar to
pkgs/top-level/all-packages.nix, containing
overridden and/or new packages.
Overlays are similar to other methods for customizing Nixpkgs, in particular
the packageOverrides attribute described in .
Indeed, packageOverrides acts as an overlay with only the
super argument. It is therefore appropriate for basic use,
but overlays are more powerful and easier to distribute.