From 0de2d2fbcdcea47292662d2509f5d06c81288e48 Mon Sep 17 00:00:00 2001
From: Eric Litak <elitak@gmail.com>
Date: Tue, 29 Mar 2016 05:27:51 -0700
Subject: mfi: init at 2.1.11

This package has some outdated dependencies, so old versions of mongodb
and v8 had to be re-added as well.
---
 pkgs/servers/nosql/mongodb/2.4.8.nix | 45 ++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 pkgs/servers/nosql/mongodb/2.4.8.nix

(limited to 'pkgs/servers/nosql')

diff --git a/pkgs/servers/nosql/mongodb/2.4.8.nix b/pkgs/servers/nosql/mongodb/2.4.8.nix
new file mode 100644
index 000000000000..448d260bdb9d
--- /dev/null
+++ b/pkgs/servers/nosql/mongodb/2.4.8.nix
@@ -0,0 +1,45 @@
+# This derivation was resurrected from 4c8ec5e12e187347fd97b1a1a9a43eb19e009ed0
+# by elitak for use with the Ubiquiti mFi Controller package, which breaks at
+# runtime on mongodb3+ and jre8+. We will need to pull in sufficiently old
+# versions of boost and v8 to build this, as well.
+{ stdenv, fetchurl, scons, boost155, v8_3_14, gperftools, pcre, snappy }:
+with stdenv.lib;
+let
+  version = "2.4.8";
+in
+stdenv.mkDerivation rec {
+  name = "mongodb-${version}";
+
+  src = fetchurl {
+    url = "http://downloads.mongodb.org/src/mongodb-src-r${version}.tar.gz";
+    sha256 = "1p6gnharypglfp39halp72fig96fqjhakyy7m76a1prxwpjkqw7x";
+  };
+
+  nativeBuildInputs = [ scons boost155 v8_3_14 gperftools pcre snappy ];
+
+  postPatch = ''
+    substituteInPlace SConstruct \
+        --replace "Environment( BUILD_DIR" "Environment( ENV = os.environ, BUILD_DIR" \
+        --replace 'CCFLAGS=["-Werror", "-pipe"]' 'CCFLAGS=["-pipe"]'
+  '';
+
+  NIX_CFLAGS_COMPILE = "-Wno-unused-local-typedefs";
+
+  buildPhase = ''
+    export SCONSFLAGS="-j$NIX_BUILD_CORES"
+    scons all --use-system-all
+  '';
+
+  installPhase = ''
+    mkdir -p $out/lib
+    scons install --use-system-all --full --prefix=$out
+  '';
+
+  meta = {
+    description = "A scalable, high-performance, open source NoSQL database";
+    homepage = http://www.mongodb.org;
+    license = licenses.agpl3;
+    maintainers = with maintainers; [ bluescreen303 elitak ];
+    platforms = platforms.linux;
+  };
+}
-- 
cgit 1.4.1