From 3cd8f05e0c9c04783ea94d0ab870e80423afa759 Mon Sep 17 00:00:00 2001
From: Markus Hauck <markus1189@gmail.com>
Date: Thu, 22 Feb 2018 20:01:34 +0100
Subject: insomnia: init at 5.14.7

---
 pkgs/development/web/insomnia/default.nix | 66 +++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 pkgs/development/web/insomnia/default.nix

(limited to 'pkgs/development')

diff --git a/pkgs/development/web/insomnia/default.nix b/pkgs/development/web/insomnia/default.nix
new file mode 100644
index 000000000000..45cf993f25ed
--- /dev/null
+++ b/pkgs/development/web/insomnia/default.nix
@@ -0,0 +1,66 @@
+{ stdenv, lib, makeWrapper, fetchurl, dpkg,
+
+  alsaLib, atk, cairo, cups, dbus_daemon, expat, fontconfig, freetype, gdk_pixbuf, glib, gnome2, gtk2-x11,
+  nspr, nss,
+
+  libX11, libXScrnSaver, libXcomposite, libXcursor, libXdamage, libXext, libXfixes, libXi, libXrandr,
+  libXrender, libXtst, libxcb,
+
+  libudev0-shim, glibc, curl
+}:
+
+let
+  libPath = lib.makeLibraryPath [
+    alsaLib atk cairo cups dbus_daemon.lib expat fontconfig freetype gdk_pixbuf glib gnome2.GConf gnome2.pango
+    gtk2-x11 nspr nss stdenv.cc.cc.lib libX11 libXScrnSaver libXcomposite libXcursor libXdamage libXext libXfixes
+    libXi libXrandr libXrender libXtst libxcb
+  ];
+  runtimeLibs = lib.makeLibraryPath [ libudev0-shim glibc curl ];
+in stdenv.mkDerivation rec {
+  name = "insomnia-${version}";
+  version = "5.14.7";
+
+  src = fetchurl {
+    url = "https://github.com/getinsomnia/insomnia/releases/download/v${version}/insomnia_${version}_amd64.deb";
+    sha256 = "1y6bn9kaxxplzyv7jjrcsfkrjnivjqdk5mbdp8vz32hv2bmdvzzy";
+  };
+
+  nativeBuildInputs = [ makeWrapper dpkg ];
+
+  buildPhase = ":";
+
+  unpackPhase = "dpkg-deb -x $src .";
+
+  installPhase = ''
+    mkdir -p $out/share/insomnia $out/lib $out/bin
+
+    mv usr/share/* $out/share/
+    mv opt/Insomnia/* $out/share/insomnia
+    mv $out/share/insomnia/*.so $out/lib/
+
+    ln -s $out/share/insomnia/insomnia $out/bin/insomnia
+  '';
+
+  preFixup = ''
+    for lib in $out/lib/*.so; do
+      patchelf --set-rpath "$out/lib:${libPath}" $lib
+    done
+
+    for bin in $out/bin/insomnia; do
+      patchelf --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
+               --set-rpath "$out/lib:${libPath}" \
+               $bin
+    done
+
+    wrapProgram "$out/bin/insomnia" --prefix LD_LIBRARY_PATH : ${runtimeLibs}
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = https://insomnia.rest/;
+    description = "The most intuitive cross-platform REST API Client";
+    license = stdenv.lib.licenses.mit;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with maintainers; [ markus1189 ];
+  };
+
+}
-- 
cgit 1.4.1