From 35586e4eecc5f9f5f6021fbd7662ac848c2faa92 Mon Sep 17 00:00:00 2001
From: Donovan Glover <donovan@dglover.co>
Date: Wed, 13 Mar 2024 05:42:23 -0400
Subject: qdirstat: migrate to by-name

---
 pkgs/by-name/qd/qdirstat/package.nix | 58 ++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 pkgs/by-name/qd/qdirstat/package.nix

(limited to 'pkgs/by-name')

diff --git a/pkgs/by-name/qd/qdirstat/package.nix b/pkgs/by-name/qd/qdirstat/package.nix
new file mode 100644
index 000000000000..f77cfcd47971
--- /dev/null
+++ b/pkgs/by-name/qd/qdirstat/package.nix
@@ -0,0 +1,58 @@
+{ lib, fetchFromGitHub, libsForQt5
+, coreutils, xdg-utils, bash
+, makeWrapper, perlPackages }:
+
+let
+  pname = "qdirstat";
+  version = "1.9";
+
+  src = fetchFromGitHub {
+    owner = "shundhammer";
+    repo = pname;
+    rev = version;
+    sha256 = "sha256-pwdmltHDNwUMx1FNOoiXl5Pna0zlKqahmicBCN6UVSU=";
+  };
+in
+
+libsForQt5.mkDerivation {
+  inherit pname version src;
+
+  nativeBuildInputs = [ libsForQt5.qmake makeWrapper ];
+
+  buildInputs = [ perlPackages.perl ];
+
+  postPatch = ''
+    substituteInPlace scripts/scripts.pro \
+      --replace /bin/true ${coreutils}/bin/true
+
+    for i in src/SysUtil.cpp src/FileSizeStatsWindow.cpp
+    do
+      substituteInPlace $i \
+        --replace /usr/bin/xdg-open ${xdg-utils}/bin/xdg-open
+    done
+    for i in src/Cleanup.cpp src/cleanup-config-page.ui
+    do
+      substituteInPlace $i \
+        --replace /bin/bash ${bash}/bin/bash \
+        --replace /bin/sh ${bash}/bin/sh
+    done
+    substituteInPlace src/StdCleanup.cpp \
+      --replace /bin/bash ${bash}/bin/bash
+  '';
+
+  qmakeFlags = [ "INSTALL_PREFIX=${placeholder "out"}" ];
+
+  postInstall = ''
+    wrapProgram $out/bin/qdirstat-cache-writer \
+      --set PERL5LIB "${perlPackages.makePerlPath [ perlPackages.URI ]}"
+  '';
+
+  meta = with lib; {
+    description = "Graphical disk usage analyzer";
+    homepage = src.meta.homepage;
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ donovanglover ];
+    platforms = platforms.linux;
+    mainProgram = "qdirstat";
+  };
+}
-- 
cgit 1.4.1


From 9fa8215790a5a3059382aa96f3c052aa614502fc Mon Sep 17 00:00:00 2001
From: Donovan Glover <donovan@dglover.co>
Date: Wed, 13 Mar 2024 05:54:57 -0400
Subject: qdirstat: cleanup

---
 pkgs/by-name/qd/qdirstat/package.nix | 29 ++++++++++++++++-------------
 1 file changed, 16 insertions(+), 13 deletions(-)

(limited to 'pkgs/by-name')

diff --git a/pkgs/by-name/qd/qdirstat/package.nix b/pkgs/by-name/qd/qdirstat/package.nix
index f77cfcd47971..e933cafc2e80 100644
--- a/pkgs/by-name/qd/qdirstat/package.nix
+++ b/pkgs/by-name/qd/qdirstat/package.nix
@@ -1,23 +1,26 @@
-{ lib, fetchFromGitHub, libsForQt5
-, coreutils, xdg-utils, bash
-, makeWrapper, perlPackages }:
-
-let
+{
+  lib,
+  fetchFromGitHub,
+  libsForQt5,
+  coreutils,
+  xdg-utils,
+  bash,
+  makeWrapper,
+  perlPackages,
+}:
+
+libsForQt5.mkDerivation rec {
   pname = "qdirstat";
   version = "1.9";
 
   src = fetchFromGitHub {
     owner = "shundhammer";
-    repo = pname;
+    repo = "qdirstat";
     rev = version;
-    sha256 = "sha256-pwdmltHDNwUMx1FNOoiXl5Pna0zlKqahmicBCN6UVSU=";
+    hash = "sha256-pwdmltHDNwUMx1FNOoiXl5Pna0zlKqahmicBCN6UVSU=";
   };
-in
-
-libsForQt5.mkDerivation {
-  inherit pname version src;
 
-  nativeBuildInputs = [ libsForQt5.qmake makeWrapper ];
+  nativeBuildInputs = [ makeWrapper ] ++ (with libsForQt5; [ qmake ]);
 
   buildInputs = [ perlPackages.perl ];
 
@@ -49,7 +52,7 @@ libsForQt5.mkDerivation {
 
   meta = with lib; {
     description = "Graphical disk usage analyzer";
-    homepage = src.meta.homepage;
+    homepage = "https://github.com/shundhammer/qdirstat";
     license = licenses.gpl2Plus;
     maintainers = with maintainers; [ donovanglover ];
     platforms = platforms.linux;
-- 
cgit 1.4.1