From 8b812ffa634a00f54bce63d80e1cdc2f48971448 Mon Sep 17 00:00:00 2001
From: Alyssa Ross <hi@alyssa.is>
Date: Sun, 10 Feb 2019 19:53:53 +0000
Subject: carla: init at 2.0-RC3

---
 nixpkgs/pkgs/applications/audio/carla/default.nix | 67 +++++++++++++++++++++++
 nixpkgs/pkgs/top-level/all-packages.nix           |  2 +
 2 files changed, 69 insertions(+)
 create mode 100644 nixpkgs/pkgs/applications/audio/carla/default.nix

(limited to 'nixpkgs')

diff --git a/nixpkgs/pkgs/applications/audio/carla/default.nix b/nixpkgs/pkgs/applications/audio/carla/default.nix
new file mode 100644
index 000000000000..8a1fef2d9c3d
--- /dev/null
+++ b/nixpkgs/pkgs/applications/audio/carla/default.nix
@@ -0,0 +1,67 @@
+{ stdenv, lib, fetchFromGitHub, pkgconfig, which
+
+, frontEndSupport ? true, python3Packages
+, OSCSupport ? true, liblo
+, binaryDetectSupport ? true, file
+
+, alsaSupport ? frontEndSupport, alsaLib
+, pulseaudioSupport ? false, pulseaudio
+
+, gtk2Support ? false, gtk2
+, gtk3Support ? false, gtk3
+, qt4Support ? false, qt4
+, qt5Support ? frontEndSupport, qt5
+
+, basicFileFormatsSupport ? true, libsndfile
+, extraFileFormatsSupport ? true, ffmpeg
+, SF23Support ? true, fluidsynth
+
+}:
+
+assert basicFileFormatsSupport -> binaryDetectSupport;
+assert frontEndSupport -> alsaSupport;
+assert frontEndSupport -> qt5Support;
+
+stdenv.mkDerivation {
+  pname = "Carla";
+  version = "2.0-RC3";
+
+  src = fetchFromGitHub {
+    owner = "falkTX";
+    repo = "Carla";
+    rev = "v1.9.13"; # Yes, tags are numbered differently than versions.
+    sha256 = "1n4xaibyq5k898rz3swl1l3dc7fjklihrzfp3jn6bf7cczf0kz45";
+  };
+
+  nativeBuildInputs = [ pkgconfig which ]
+    ++ lib.optional frontEndSupport python3Packages.pyqt5
+    ;
+
+  buildInputs = [ ]
+    ++ lib.optional frontEndSupport python3Packages.pyqt5
+    ++ lib.optional OSCSupport liblo
+    ++ lib.optional binaryDetectSupport file
+
+    ++ lib.optional alsaSupport alsaLib
+    ++ lib.optional pulseaudioSupport pulseaudio
+
+    ++ lib.optional gtk2Support gtk2
+    ++ lib.optional gtk3Support gtk3
+    ++ lib.optional qt4Support qt4
+    ++ lib.optional qt5Support qt5.qtbase
+
+    ++ lib.optional basicFileFormatsSupport libsndfile
+    ++ lib.optional extraFileFormatsSupport ffmpeg
+    ++ lib.optional SF23Support fluidsynth
+    ;
+
+  installFlags = [ "PREFIX=$(out)" ];
+
+  meta = with lib; {
+    description = "Audio plugin host";
+    homepage = https://kxstudio.linuxaudio.org/Applications:Carla;
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ qyliss ];
+    platforms = platforms.all;
+  };
+}
diff --git a/nixpkgs/pkgs/top-level/all-packages.nix b/nixpkgs/pkgs/top-level/all-packages.nix
index 8d09bf65f6c3..57666734c620 100644
--- a/nixpkgs/pkgs/top-level/all-packages.nix
+++ b/nixpkgs/pkgs/top-level/all-packages.nix
@@ -16331,6 +16331,8 @@ in
 
   carddav-util = callPackage ../tools/networking/carddav-util { };
 
+  carla = callPackage ../applications/audio/carla { };
+
   catfish = callPackage ../applications/search/catfish { };
 
   cava = callPackage ../applications/audio/cava { };
-- 
cgit 1.4.1