From b54987715bf9240622a4d135217fe2201d7cd3d0 Mon Sep 17 00:00:00 2001
From: Yegor Timoshenko <yegortimoshenko@gmail.com>
Date: Sat, 6 Jan 2018 13:25:13 +0000
Subject: weechat: add NixOS module

---
 nixos/modules/services/misc/weechat.nix | 67 +++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 nixos/modules/services/misc/weechat.nix

(limited to 'nixos/modules/services/misc/weechat.nix')

diff --git a/nixos/modules/services/misc/weechat.nix b/nixos/modules/services/misc/weechat.nix
new file mode 100644
index 000000000000..535a7f9ef91f
--- /dev/null
+++ b/nixos/modules/services/misc/weechat.nix
@@ -0,0 +1,67 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.services.weechat;
+in
+
+{
+  options.services.weechat = {
+    enable = mkEnableOption "weechat";
+    init = mkOption {
+      description = "Weechat commands applied at start, one command per line.";
+      example = ''
+        /set relay.network.password correct-horse-battery-staple
+        /relay add weechat 9001
+      '';
+      type = types.str;
+      default = "";
+    };
+    root = mkOption {
+      description = "Weechat state directory.";
+      type = types.str;
+      default = "/var/lib/weechat";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    users = {
+      users.weechat = {
+        createHome = true;
+        group = "weechat";
+        home = cfg.root;
+      };
+    };
+
+    systemd.services.weechat = {
+      environment.WEECHAT_HOME = cfg.root;
+      serviceConfig = {
+        User = "weechat";
+        Group = "weechat";
+      };
+      script = "exec ${pkgs.screen}/bin/screen -D -m ${pkgs.weechat}/bin/weechat";
+      wantedBy = [ "multi-user.target" ];
+      wants = [ "network.target" ];
+    };
+
+    systemd.paths.weechat-fifo = {
+      pathConfig = {
+        PathExists = "${cfg.root}/weechat_fifo";
+        Unit = "weechat-apply-init.service";
+      };
+      wantedBy = [ "multi-user.target" ];
+    };
+
+    systemd.services.weechat-apply-init = let
+      initFile = pkgs.writeText "weechat-init" cfg.init;
+    in {
+      script = "sed 's/^/*/' ${initFile} > ${cfg.root}/weechat_fifo";
+      serviceConfig = {
+        Type = "oneshot";
+        User = "weechat";
+        Group = "weechat";
+      };
+    };
+  };
+}
-- 
cgit 1.4.1