From 7b9a553e21d53069a86600d9274c0201ee06767e Mon Sep 17 00:00:00 2001
From: zimbatm <zimbatm@zimbatm.com>
Date: Sun, 17 Dec 2017 20:32:56 +0000
Subject: nixos: move system.autoUpgrade

This is not installer-specific
---
 nixos/modules/installer/tools/auto-upgrade.nix | 92 --------------------------
 1 file changed, 92 deletions(-)
 delete mode 100644 nixos/modules/installer/tools/auto-upgrade.nix

(limited to 'nixos/modules/installer')

diff --git a/nixos/modules/installer/tools/auto-upgrade.nix b/nixos/modules/installer/tools/auto-upgrade.nix
deleted file mode 100644
index 7b756b70e2fc..000000000000
--- a/nixos/modules/installer/tools/auto-upgrade.nix
+++ /dev/null
@@ -1,92 +0,0 @@
-{ config, lib, pkgs, ... }:
-
-with lib;
-
-let cfg = config.system.autoUpgrade; in
-
-{
-
-  options = {
-
-    system.autoUpgrade = {
-
-      enable = mkOption {
-        type = types.bool;
-        default = false;
-        description = ''
-          Whether to periodically upgrade NixOS to the latest
-          version. If enabled, a systemd timer will run
-          <literal>nixos-rebuild switch --upgrade</literal> once a
-          day.
-        '';
-      };
-
-      channel = mkOption {
-        type = types.nullOr types.str;
-        default = null;
-        example = https://nixos.org/channels/nixos-14.12-small;
-        description = ''
-          The URI of the NixOS channel to use for automatic
-          upgrades. By default, this is the channel set using
-          <command>nix-channel</command> (run <literal>nix-channel
-          --list</literal> to see the current value).
-        '';
-      };
-
-      flags = mkOption {
-        type = types.listOf types.str;
-        default = [];
-        example = [ "-I" "stuff=/home/alice/nixos-stuff" "--option" "extra-binary-caches" "http://my-cache.example.org/" ];
-        description = ''
-          Any additional flags passed to <command>nixos-rebuild</command>.
-        '';
-      };
-
-      dates = mkOption {
-        default = "04:40";
-        type = types.str;
-        description = ''
-          Specification (in the format described by
-          <citerefentry><refentrytitle>systemd.time</refentrytitle>
-          <manvolnum>7</manvolnum></citerefentry>) of the time at
-          which the update will occur.
-        '';
-      };
-
-    };
-
-  };
-
-  config = {
-
-    system.autoUpgrade.flags =
-      [ "--no-build-output" ]
-      ++ (if cfg.channel == null
-          then [ "--upgrade" ]
-          else [ "-I" "nixpkgs=${cfg.channel}/nixexprs.tar.xz" ]);
-
-    systemd.services.nixos-upgrade = {
-      description = "NixOS Upgrade";
-
-      restartIfChanged = false;
-      unitConfig.X-StopOnRemoval = false;
-
-      serviceConfig.Type = "oneshot";
-
-      environment = config.nix.envVars //
-        { inherit (config.environment.sessionVariables) NIX_PATH;
-          HOME = "/root";
-        } // config.networking.proxy.envVars;
-
-      path = [ pkgs.gnutar pkgs.xz.bin config.nix.package.out ];
-
-      script = ''
-        ${config.system.build.nixos-rebuild}/bin/nixos-rebuild switch ${toString cfg.flags}
-      '';
-
-      startAt = optional cfg.enable cfg.dates;
-    };
-
-  };
-
-}
-- 
cgit 1.4.1