From a83eadd81c1978a6f6235a31e7fe79c0bbf18b1a Mon Sep 17 00:00:00 2001
From: Jookia <166291@gmail.com>
Date: Wed, 3 Aug 2016 08:56:10 +1000
Subject: htpdate: init at 1.1.3

---
 pkgs/tools/networking/htpdate/default.nix | 24 ++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix           |  2 ++
 2 files changed, 26 insertions(+)
 create mode 100644 pkgs/tools/networking/htpdate/default.nix

diff --git a/pkgs/tools/networking/htpdate/default.nix b/pkgs/tools/networking/htpdate/default.nix
new file mode 100644
index 000000000000..10ed8f34e3a6
--- /dev/null
+++ b/pkgs/tools/networking/htpdate/default.nix
@@ -0,0 +1,24 @@
+{ stdenv, fetchurl, coreutils, binutils }:
+
+stdenv.mkDerivation rec {
+  version = "1.1.3";
+  name = "htpdate-${version}";
+
+  src = fetchurl {
+    url = "http://twekkel.home.xs4all.nl/htp/htpdate-${version}.tar.gz";
+    sha256 = "0hfg4qrsmpqw03m9qwf3zgi4brbf65w6wd3w30nkamc7x8b4vn5i";
+  };
+
+  installFlags = [
+    "INSTALL=${coreutils}/bin/install"
+    "STRIP=${binutils}/bin/strip"
+    "prefix=$(out)"
+  ];
+
+  meta = {
+    description = "Utility to fetch time and set the system clock over HTTP";
+    homepage = http://www.vervest.org/htp/;
+    platforms = stdenv.lib.platforms.linux;
+    license = stdenv.lib.licenses.gpl2Plus;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 1261c3dce732..941e67c4020b 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -2064,6 +2064,8 @@ in
 
   hping = callPackage ../tools/networking/hping { };
 
+  htpdate = callPackage ../tools/networking/htpdate { };
+
   http-prompt = callPackage ../tools/networking/http-prompt { };
 
   httpie = callPackage ../tools/networking/httpie { };
-- 
cgit 1.4.1


From e23cc550b32a712d2397d005c7a906d6abf35a03 Mon Sep 17 00:00:00 2001
From: Jookia <166291@gmail.com>
Date: Wed, 3 Aug 2016 08:57:20 +1000
Subject: nixos: add htpdate module

---
 nixos/modules/module-list.nix                 |  1 +
 nixos/modules/services/networking/htpdate.nix | 80 +++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)
 create mode 100644 nixos/modules/services/networking/htpdate.nix

diff --git a/nixos/modules/module-list.nix b/nixos/modules/module-list.nix
index 7064dcd968ae..a3bbddfcdd21 100644
--- a/nixos/modules/module-list.nix
+++ b/nixos/modules/module-list.nix
@@ -354,6 +354,7 @@
   ./services/networking/haproxy.nix
   ./services/networking/heyefi.nix
   ./services/networking/hostapd.nix
+  ./services/networking/htpdate.nix
   ./services/networking/i2pd.nix
   ./services/networking/i2p.nix
   ./services/networking/iodine.nix
diff --git a/nixos/modules/services/networking/htpdate.nix b/nixos/modules/services/networking/htpdate.nix
new file mode 100644
index 000000000000..f5d512c7cd5a
--- /dev/null
+++ b/nixos/modules/services/networking/htpdate.nix
@@ -0,0 +1,80 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  inherit (pkgs) htpdate;
+
+  cfg = config.services.htpdate;
+in
+
+{
+
+  ###### interface
+
+  options = {
+
+    services.htpdate = {
+
+      enable = mkOption {
+        type = types.bool;
+        default = false;
+        description = ''
+          Enable htpdate daemon.
+        '';
+      };
+
+      extraOptions = mkOption {
+        type = types.str;
+        default = "";
+        description = ''
+          Additional command line arguments to pass to htpdate.
+        '';
+      };
+
+      servers = mkOption {
+        type = types.listOf types.str;
+        default = [ "www.google.com" ];
+        description = ''
+          HTTP servers to use for time synchronization.
+        '';
+      };
+
+      proxy = mkOption {
+        type = types.str;
+        default = "";
+        example = "127.0.0.1:8118";
+        description = ''
+          HTTP proxy used for requests.
+        '';
+      };
+
+    };
+
+  };
+
+  ###### implementation
+
+  config = mkIf cfg.enable {
+
+    systemd.services.htpdate = {
+      description = "htpdate daemon";
+      wantedBy = [ "multi-user.target" ];
+      serviceConfig = {
+        Type = "forking";
+        PIDFile = "/var/run/htpdate.pid";
+        ExecStart = concatStringsSep " " [
+          "${htpdate}/bin/htpdate"
+          "-D -u nobody"
+          "-a -s"
+          "-l"
+          "${optionalString (cfg.proxy != "") "-P ${cfg.proxy}"}"
+          "${cfg.extraOptions}"
+          "${concatStringsSep " " cfg.servers}"
+        ];
+      };
+    };
+
+  };
+
+}
-- 
cgit 1.4.1