From 0c9c74de19847f5524ccf589a76e6a943e7e3bef Mon Sep 17 00:00:00 2001
From: Nikolay Amiantov <ab@fmap.me>
Date: Fri, 2 Jan 2015 18:11:29 +0300
Subject: tlp: add package

---
 pkgs/tools/misc/tlp/default.nix | 65 +++++++++++++++++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix |  4 +++
 2 files changed, 69 insertions(+)
 create mode 100644 pkgs/tools/misc/tlp/default.nix

diff --git a/pkgs/tools/misc/tlp/default.nix b/pkgs/tools/misc/tlp/default.nix
new file mode 100644
index 000000000000..d251c7cdd94b
--- /dev/null
+++ b/pkgs/tools/misc/tlp/default.nix
@@ -0,0 +1,65 @@
+{ stdenv, fetchFromGitHub, makeWrapper, perl, systemd, iw, rfkill, hdparm, ethtool, inetutils, kmod
+, enableRDW ? true, networkmanager }:
+
+let version = "0.6";
+in stdenv.mkDerivation {
+  inherit enableRDW;
+
+  name = "tlp-${version}";
+
+  src = fetchFromGitHub {
+        owner = "linrunner";
+        repo = "TLP";
+        rev = "${version}";
+        sha256 = "1kfm6x5w9vica2i13vfckza4fad4wv8ivr40fws3qa6d5jbyx0fy";
+      };
+
+  makeFlags = [ "DESTDIR=$(out)"
+                "TLP_LIBDIR=/lib"
+                "TLP_SBIN=/bin"
+                "TLP_BIN=/bin"
+                "TLP_NO_INIT=1"
+                "TLP_NO_PMUTILS=1"
+              ];
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  buildInputs = [ perl ];
+
+  paths = with stdenv.lib;
+          concatMapStringsSep ":" (x: "${x}/bin")
+          ([ iw rfkill hdparm ethtool inetutils systemd kmod ]
+           ++ optional enableRDW networkmanager
+          );
+
+  installTargets = [ "install-tlp" ] ++ stdenv.lib.optional enableRDW "install-rdw";
+
+  postInstall = ''
+    for i in $out/bin/* $out/lib/udev/tlp-*; do
+      sed -i "s,/usr/lib/,$out/lib/,g" "$i"
+      wrapProgram "$i" \
+        --prefix PATH : "$paths"
+    done
+    if [ "$enableRDW" = "1" ]; then
+      for i in $out/etc/NetworkManager/dispatcher.d/*; do
+        sed -i "s,/usr/lib/,$out/lib/,g" "$i"
+        wrapProgram "$i" \
+          --prefix PATH : "$paths"
+      done
+    fi
+
+    for i in $out/lib/udev/rules.d/*; do
+      sed -i "s,RUN+=\",\\0$out,g; s,/usr/sbin,/bin,g" "$i"
+    done
+  '';
+
+  passthru = { inherit enableRDW; };
+
+  meta = with stdenv.lib; {
+    description = "Advanced Power Management for Linux";
+    homepage = "http://linrunner.de/en/tlp/docs/tlp-linux-advanced-power-management.html";
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ abbradar ];
+    license = licenses.gpl2Plus;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 14a057ef1358..a0d7cf912d6a 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -11019,6 +11019,10 @@ let
 
   tla = callPackage ../applications/version-management/arch { };
 
+  tlp = callPackage ../tools/misc/tlp {
+    enableRDW = config.networking.networkmanager.enable or false;
+  };
+
   todo-txt-cli = callPackage ../applications/office/todo.txt-cli { };
 
   tomahawk = callPackage ../applications/audio/tomahawk {
-- 
cgit 1.4.1