1 files changed, 35 insertions, 0 deletions
diff --git a/pkgs/development/libraries/gstreamer/libav/default.nix b/pkgs/development/libraries/gstreamer/libav/default.nix
new file mode 100644
index 000000000000..47be4c8f4a05
--- /dev/null
+++ b/pkgs/development/libraries/gstreamer/libav/default.nix
@@ -0,0 +1,35 @@
+{ stdenv, fetchurl, pkgconfig, python, yasm
+, gst-plugins-base, orc, bzip2
+, withSystemLibav ? true, libav ? null
+}:
+
+assert withSystemLibav -> libav != null;
+
+stdenv.mkDerivation rec {
+  name = "gst-libav-1.2.2";
+
+  meta = {
+    homepage = "http://gstreamer.freedesktop.org";
+    license = stdenv.lib.licenses.lgpl2Plus;
+    platforms = stdenv.lib.platforms.linux;
+    maintainers = with stdenv.lib.maintainers; [ iyzsong ];
+  };
+
+  src = fetchurl {
+    url = "${meta.homepage}/src/gst-libav/${name}.tar.xz";
+    sha256 = "585eb7971006100ad771a852e07bd2f3e23bcc6eb0b1253a40b5a0e40e4e7418";
+  };
+
+  configureFlags = stdenv.lib.optionalString withSystemLibav
+    "--with-system-libav";
+
+  nativeBuildInputs = with stdenv.lib;
+    [ pkgconfig python ]
+    ++ optional (!withSystemLibav) yasm
+    ;
+
+  buildInputs = with stdenv.lib;
+    [ gst-plugins-base orc bzip2 ]
+    ++ optional withSystemLibav libav
+    ;
+}