5 files changed, 0 insertions, 235 deletions
diff --git a/pkgs/development/compilers/corretto/11.nix b/pkgs/development/compilers/corretto/11.nix
deleted file mode 100644
index b7bd676143c0..000000000000
--- a/pkgs/development/compilers/corretto/11.nix
+++ /dev/null
@@ -1,31 +0,0 @@
-{ fetchFromGitHub
-, gradle_7
-, jdk11
-, lib
-, stdenv
-, rsync
-, runCommand
-, testers
-}:
-
-let
-  corretto = import ./mk-corretto.nix rec {
-    inherit lib stdenv rsync runCommand testers;
-    jdk = jdk11;
-    gradle = gradle_7;
-    extraConfig = [
-      # jdk11 is built with --disable-warnings-as-errors (see openjdk/11.nix)
-      # because of several compile errors. We need to include this parameter for
-      # Corretto, too.
-      "--disable-warnings-as-errors"
-    ];
-    version = "11.0.23.9.1";
-    src = fetchFromGitHub {
-      owner = "corretto";
-      repo = "corretto-11";
-      rev = version;
-      sha256 = "sha256-qSx0kgXTgvsvBaEqgy7Jrp/c1Imoi5/IOqEWoLenJYI=";
-    };
-  };
-in
-corretto
diff --git a/pkgs/development/compilers/corretto/17.nix b/pkgs/development/compilers/corretto/17.nix
deleted file mode 100644
index c557012e8cdb..000000000000
--- a/pkgs/development/compilers/corretto/17.nix
+++ /dev/null
@@ -1,34 +0,0 @@
-{ fetchFromGitHub
-, fetchurl
-, gradle_7
-, jdk17
-, lib
-, stdenv
-, rsync
-, runCommand
-, testers
-}:
-
-let
-  corretto = import ./mk-corretto.nix rec {
-    inherit lib stdenv rsync runCommand testers;
-    jdk = jdk17;
-    gradle = gradle_7;
-    version = "17.0.11.9.1";
-    src = fetchFromGitHub {
-      owner = "corretto";
-      repo = "corretto-17";
-      rev = version;
-      sha256 = "sha256-LxZSFILFfyh8oBiYEnuBQ0Og2i713qdK2jIiCBnrlj0=";
-    };
-  };
-in
-corretto.overrideAttrs (final: prev: {
-  # HACK: Removes the FixNullPtrCast patch, as it fails to apply. Need to figure out what causes it to fail to apply.
-  patches = lib.remove
-    (fetchurl {
-      url = "https://git.alpinelinux.org/aports/plain/community/openjdk17/FixNullPtrCast.patch?id=41e78a067953e0b13d062d632bae6c4f8028d91c";
-      sha256 = "sha256-LzmSew51+DyqqGyyMw2fbXeBluCiCYsS1nCjt9hX6zo=";
-    })
-    (prev.patches or [ ]);
-})
diff --git a/pkgs/development/compilers/corretto/19.nix b/pkgs/development/compilers/corretto/19.nix
deleted file mode 100644
index 0674b63f21df..000000000000
--- a/pkgs/development/compilers/corretto/19.nix
+++ /dev/null
@@ -1,25 +0,0 @@
-{ fetchFromGitHub
-, gradle_7
-, jdk19
-, lib
-, stdenv
-, rsync
-, runCommand
-, testers
-}:
-
-let
-  corretto = import ./mk-corretto.nix rec {
-    inherit lib stdenv rsync runCommand testers;
-    jdk = jdk19;
-    gradle = gradle_7;
-    version = "19.0.2.7.1";
-    src = fetchFromGitHub {
-      owner = "corretto";
-      repo = "corretto-19";
-      rev = version;
-      sha256 = "sha256-mEj/MIbdXU0+fF5RhqjPuSeyclstesGaXB0e48YlKuw=";
-    };
-  };
-in
-corretto
diff --git a/pkgs/development/compilers/corretto/21.nix b/pkgs/development/compilers/corretto/21.nix
deleted file mode 100644
index 9656ace73cef..000000000000
--- a/pkgs/development/compilers/corretto/21.nix
+++ /dev/null
@@ -1,26 +0,0 @@
-{ corretto21
-, fetchFromGitHub
-, gradle_7
-, jdk21
-, lib
-, stdenv
-, rsync
-, runCommand
-, testers
-}:
-
-let
-  corretto = import ./mk-corretto.nix rec {
-    inherit lib stdenv rsync runCommand testers;
-    jdk = jdk21;
-    gradle = gradle_7;
-    version = "21.0.3.9.1";
-    src = fetchFromGitHub {
-      owner = "corretto";
-      repo = "corretto-21";
-      rev = version;
-      sha256 = "sha256-V8UDyukDCQVTWUg4IpSKoY0qnnQ5fePbm3rxcw06Vr0=";
-    };
-  };
-in
-corretto
diff --git a/pkgs/development/compilers/corretto/mk-corretto.nix b/pkgs/development/compilers/corretto/mk-corretto.nix
deleted file mode 100644
index c26614e47641..000000000000
--- a/pkgs/development/compilers/corretto/mk-corretto.nix
+++ /dev/null
@@ -1,119 +0,0 @@
-{ jdk
-, version
-, src
-, lib
-, stdenv
-, gradle
-, extraConfig ? [ ]
-, rsync
-, runCommand
-, testers
-}:
-
-# Each Corretto version is based on a corresponding OpenJDK version. So
-# building Corretto is more or less the same as building OpenJDK. Hence, the
-# Corretto derivation overrides the corresponding OpenJDK derivation in order
-# to have access to all the version-specific fixes for the various OpenJDK
-# builds. However, Corretto uses `gradle` as build tool (which in turn will
-# invoke `make`). The configure/build phases are adapted as needed.
-
-let
-  pname = "corretto";
-  # The version scheme is different between OpenJDK & Corretto.
-  # See https://github.com/corretto/corretto-17/blob/release-17.0.8.8.1/build.gradle#L40
-  # "major.minor.security.build.revision"
-in
-jdk.overrideAttrs (finalAttrs: oldAttrs: {
-  inherit pname version src;
-  name = "${pname}-${version}";
-
-  nativeBuildInputs = oldAttrs.nativeBuildInputs ++ [ jdk gradle rsync ];
-
-  dontConfigure = true;
-
-  postPatch = ''
-    # The rpm/deb task definitions require a Gradle plugin which we don't
-    # have and so the build fails. We'll simply remove them here because
-    # they are not needed anyways.
-    rm -rf installers/linux/universal/{rpm,deb}
-
-    # `/usr/bin/rsync` is invoked to copy the source tree. We don't have that.
-    for file in $(find installers -name "build.gradle"); do
-      substituteInPlace $file --replace-warn "workingDir '/usr/bin'" "workingDir '.'"
-    done
-  '';
-
-
-  buildPhase =
-    let
-      # The Linux installer is placed at linux/universal/tar whereas the MacOS
-      # one is at mac/tar.
-      task =
-        if stdenv.isDarwin then
-          ":installers:mac:tar:packageBuildResults"
-        else ":installers:linux:universal:tar:packageBuildResults";
-      extra_config = builtins.concatStringsSep " " extraConfig;
-    in
-    ''
-      runHook preBuild
-
-      # Corretto's actual built is triggered via `gradle`.
-      gradle -Pcorretto.extra_config="${extra_config}" --console=plain --no-daemon ${task}
-
-      # Prepare for the installPhase so that it looks like if a normal
-      # OpenJDK had been built.
-      dir=build/jdkImageName/images
-      mkdir -p $dir
-      file=$(find ./installers -name 'amazon-corretto-${version}*.tar.gz')
-      tar -xzf $file -C $dir
-      mv $dir/amazon-corretto-* $dir/jdk
-
-      runHook postBuild
-    '';
-
-  installPhase = oldAttrs.installPhase + ''
-    # The installPhase will place everything in $out/lib/openjdk and
-    # reference through symlinks. We don't rewrite the installPhase but at
-    # least move the folder to convey that this is not OpenJDK anymore.
-    mv $out/lib/openjdk $out/lib/corretto
-    ln -s $out/lib/corretto $out/lib/openjdk
-  '';
-
-  passthru =
-    let
-      pkg = finalAttrs.finalPackage;
-    in
-    oldAttrs.passthru // {
-      tests = {
-        version = testers.testVersion {
-          package = pkg;
-        };
-        vendor = runCommand "${pname}-vendor" { nativeBuildInputs = [ pkg ]; } ''
-          output=$(${pkg.meta.mainProgram} -XshowSettings:properties -version 2>&1 | grep vendor)
-          grep -Fq "java.vendor = Amazon.com Inc." - <<< "$output" && touch $out
-        '';
-        compiler = runCommand "${pname}-compiler" { nativeBuildInputs = [ pkg ]; } ''
-          cat << EOF  > Main.java
-          class Main {
-              public static void main(String[] args) {
-                  System.out.println("Hello, World!");
-              }
-          }
-          EOF
-          ${pkg}/bin/javac Main.java
-          ${pkg}/bin/java Main | grep -q "Hello, World!" && touch $out
-        '';
-      };
-    };
-
-
-  # Some of the OpenJDK derivation set their `pos` by hand. We need to
-  # overwrite this in order to point to Corretto, not OpenJDK.
-  pos = __curPos;
-  meta = with lib; oldAttrs.meta // {
-    homepage = "https://aws.amazon.com/corretto";
-    license = licenses.gpl2Only;
-    description = "Amazon's distribution of OpenJDK";
-    maintainers = with maintainers; [ rollf ];
-  };
-})