1 files changed, 41 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/tools/security/sshuttle/default.nix b/nixpkgs/pkgs/tools/security/sshuttle/default.nix
new file mode 100644
index 000000000000..0e0e8c7ad753
--- /dev/null
+++ b/nixpkgs/pkgs/tools/security/sshuttle/default.nix
@@ -0,0 +1,41 @@
+{ stdenv, python3Packages, fetchurl, makeWrapper
+, coreutils, iptables, nettools, openssh, procps }:
+
+python3Packages.buildPythonApplication rec {
+  name = "sshuttle-${version}";
+  version = "0.78.5";
+
+  src = fetchurl {
+    sha256 = "0vp13xwrhx4m6zgsyzvai84lkq9mzkaw47j58dk0ll95kaymk2x8";
+    url = "mirror://pypi/s/sshuttle/${name}.tar.gz";
+  };
+
+  patches = [ ./sudo.patch ];
+
+  nativeBuildInputs = [ makeWrapper python3Packages.setuptools_scm ];
+  buildInputs =
+    [ coreutils openssh procps nettools ]
+    ++ stdenv.lib.optionals stdenv.isLinux [ iptables ];
+
+  checkInputs = with python3Packages; [ mock pytest pytestcov pytestrunner flake8 ];
+
+  postInstall = let
+    mapPath = f: x: stdenv.lib.concatStringsSep ":" (map f x);
+  in ''
+  wrapProgram $out/bin/sshuttle \
+    --prefix PATH : "${mapPath (x: "${x}/bin") buildInputs}" \
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = https://github.com/sshuttle/sshuttle/;
+    description = "Transparent proxy server that works as a poor man's VPN";
+    longDescription = ''
+      Forward connections over SSH, without requiring administrator access to the
+      target network (though it does require Python 2.7, Python 3.5 or later at both ends).
+      Works with Linux and Mac OS and supports DNS tunneling.
+    '';
+    license = licenses.gpl2;
+    maintainers = with maintainers; [ domenkozar carlosdagos ];
+    platforms = platforms.unix;
+  };
+}