1 files changed, 80 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/tools/misc/tmux/default.nix b/nixpkgs/pkgs/tools/misc/tmux/default.nix
new file mode 100644
index 000000000000..c76912e3c909
--- /dev/null
+++ b/nixpkgs/pkgs/tools/misc/tmux/default.nix
@@ -0,0 +1,80 @@
+{ lib, stdenv
+, fetchFromGitHub
+, autoreconfHook
+, pkg-config
+, bison
+, ncurses
+, libevent
+}:
+
+let
+
+  bashCompletion = fetchFromGitHub {
+    owner = "imomaliev";
+    repo = "tmux-bash-completion";
+    rev = "f5d53239f7658f8e8fbaf02535cc369009c436d6";
+    sha256 = "0sq2g3w0h3mkfa6qwqdw93chb5f1hgkz5vdl8yw8mxwdqwhsdprr";
+  };
+
+in
+
+stdenv.mkDerivation rec {
+  pname = "tmux";
+  version = "3.2a";
+
+  outputs = [ "out" "man" ];
+
+  src = fetchFromGitHub {
+    owner = "tmux";
+    repo = "tmux";
+    rev = version;
+    sha256 = "0143ylfk7zsl3xmiasb768238gr582cfhsgv3p0h0f13bp8d6q09";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    autoreconfHook
+    bison
+  ];
+
+  buildInputs = [
+    ncurses
+    libevent
+  ];
+
+  configureFlags = [
+    "--sysconfdir=/etc"
+    "--localstatedir=/var"
+  ];
+
+  enableParallelBuilding = true;
+
+  postInstall = ''
+    mkdir -p $out/share/bash-completion/completions
+    cp -v ${bashCompletion}/completions/tmux $out/share/bash-completion/completions/tmux
+  '';
+
+  meta = {
+    homepage = "https://tmux.github.io/";
+    description = "Terminal multiplexer";
+
+    longDescription =
+      '' tmux is intended to be a modern, BSD-licensed alternative to programs such as GNU screen. Major features include:
+
+          * A powerful, consistent, well-documented and easily scriptable command interface.
+          * A window may be split horizontally and vertically into panes.
+          * Panes can be freely moved and resized, or arranged into preset layouts.
+          * Support for UTF-8 and 256-colour terminals.
+          * Copy and paste with multiple buffers.
+          * Interactive menus to select windows, sessions or clients.
+          * Change the current window by searching for text in the target.
+          * Terminal locking, manually or after a timeout.
+          * A clean, easily extended, BSD-licensed codebase, under active development.
+      '';
+    changelog = "https://github.com/tmux/tmux/raw/${version}/CHANGES";
+    license = lib.licenses.bsd3;
+
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ thammers fpletz ];
+  };
+}