2 files changed, 60 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/tools/backup/httrack/default.nix b/nixpkgs/pkgs/tools/backup/httrack/default.nix
new file mode 100644
index 000000000000..a01565c43a0a
--- /dev/null
+++ b/nixpkgs/pkgs/tools/backup/httrack/default.nix
@@ -0,0 +1,22 @@
+{ lib, stdenv, fetchurl, zlib, openssl, libiconv }:
+
+stdenv.mkDerivation rec {
+  version = "3.49.2";
+  pname = "httrack";
+
+  src = fetchurl {
+    url = "https://mirror.httrack.com/httrack-${version}.tar.gz";
+    sha256 = "09a0gm67nml86qby1k1gh7rdxamnrnzwr6l9r5iiq94favjs0xrl";
+  };
+
+  buildInputs = [ zlib openssl ] ++ lib.optional stdenv.isDarwin libiconv;
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    description = "Easy-to-use offline browser / website mirroring utility";
+    homepage    = "http://www.httrack.com";
+    license     = licenses.gpl3;
+    platforms   = with platforms; unix;
+  };
+}
diff --git a/nixpkgs/pkgs/tools/backup/httrack/qt.nix b/nixpkgs/pkgs/tools/backup/httrack/qt.nix
new file mode 100644
index 000000000000..2a7c4ff51768
--- /dev/null
+++ b/nixpkgs/pkgs/tools/backup/httrack/qt.nix
@@ -0,0 +1,38 @@
+{ mkDerivation, lib, fetchurl, cmake, pkg-config, makeWrapper
+, httrack, qtbase, qtmultimedia }:
+
+mkDerivation rec {
+  pname = "httraqt";
+  version = "1.4.9";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/httraqt/${pname}-${version}.tar.gz";
+    sha256 = "0pjxqnqchpbla4xiq4rklc06484n46cpahnjy03n9rghwwcad25b";
+  };
+
+  buildInputs = [ httrack qtbase qtmultimedia ];
+
+  nativeBuildInputs = [ cmake makeWrapper pkg-config ];
+
+  prePatch = ''
+    substituteInPlace cmake/HTTRAQTFindHttrack.cmake \
+      --replace /usr/include/httrack/ ${httrack}/include/httrack/
+
+    substituteInPlace distribution/posix/CMakeLists.txt \
+      --replace /usr/share $out/share
+
+    substituteInPlace desktop/httraqt.desktop \
+      --replace Exec=httraqt Exec=$out/bin/httraqt
+
+    substituteInPlace sources/main/httraqt.cpp \
+      --replace /usr/share/httraqt/ $out/share/httraqt
+  '';
+
+  meta = with lib; {
+    description = "Easy-to-use offline browser / website mirroring utility - QT frontend";
+    homepage    = "http://www.httrack.com";
+    license     = licenses.gpl3;
+    maintainers = with maintainers; [ peterhoeg ];
+    platforms   = with platforms; unix;
+  };
+}