1 files changed, 50 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/tools/backup/gyb/default.nix b/nixpkgs/pkgs/tools/backup/gyb/default.nix
new file mode 100644
index 000000000000..5f69ea016b1d
--- /dev/null
+++ b/nixpkgs/pkgs/tools/backup/gyb/default.nix
@@ -0,0 +1,50 @@
+{ lib
+, fetchFromGitHub
+, python3
+, python3Packages
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "gyb";
+  version = "1.72";
+  format = "other";
+
+  src = fetchFromGitHub {
+    owner = "GAM-team";
+    repo = "got-your-back";
+    rev = "refs/tags/v${version}";
+    sha256 = "sha256-75ZU1qNFdiX9Uhb+tKN0438iHKvY4fuFVGvcgyFFgJo=";
+  };
+
+  propagatedBuildInputs = with python3Packages; [
+    google-api-python-client
+    google-auth
+    google-auth-oauthlib
+    google-auth-httplib2
+    httplib2
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/{bin,${python3.sitePackages}}
+    mv gyb.py "$out/bin/gyb"
+    mv *.py "$out/${python3.sitePackages}/"
+
+    runHook postInstall
+  '';
+
+  checkPhase = ''
+    $out/bin/gyb --help > /dev/null
+  '';
+
+  meta = with lib; {
+    description = ''
+      Got Your Back (GYB) is a command line tool for backing up your Gmail
+      messages to your computer using Gmail's API over HTTPS.
+    '';
+    homepage = "https://github.com/GAM-team/got-your-back";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ austinbutler ];
+  };
+}