2 files changed, 53 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/tools/X11/virtualgl/default.nix b/nixpkgs/pkgs/tools/X11/virtualgl/default.nix
new file mode 100644
index 000000000000..aa839e6d684d
--- /dev/null
+++ b/nixpkgs/pkgs/tools/X11/virtualgl/default.nix
@@ -0,0 +1,24 @@
+{ stdenv, lib
+, virtualglLib
+, virtualglLib_i686 ? null
+}:
+
+stdenv.mkDerivation {
+  name = "virtualgl-${lib.getVersion virtualglLib}";
+
+  paths = [ virtualglLib ];
+
+  buildCommand = ''
+    mkdir -p $out/bin
+    for i in ${virtualglLib}/bin/* ${virtualglLib}/bin/.vglrun*; do
+      ln -s "$i" $out/bin
+    done
+  '' + lib.optionalString (virtualglLib_i686 != null) ''
+    ln -sf ${virtualglLib_i686}/bin/.vglrun.vars32 $out/bin
+  '';
+
+  meta = {
+    platforms = stdenv.lib.platforms.linux;
+    inherit (virtualglLib.meta) license;
+  };
+}
diff --git a/nixpkgs/pkgs/tools/X11/virtualgl/lib.nix b/nixpkgs/pkgs/tools/X11/virtualgl/lib.nix
new file mode 100644
index 000000000000..47b54bec312c
--- /dev/null
+++ b/nixpkgs/pkgs/tools/X11/virtualgl/lib.nix
@@ -0,0 +1,29 @@
+{ stdenv, fetchurl, cmake, libGL, libGLU, libX11, libXv, libXtst, libjpeg_turbo, fltk }:
+
+stdenv.mkDerivation rec {
+  name = "virtualgl-lib-${version}";
+  version = "2.6.2";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/virtualgl/VirtualGL-${version}.tar.gz";
+    sha256 = "0ngqwsm9bml6lis0igq3bn92amh04rccd6jhjibj3418hrbzipvr";
+  };
+
+  cmakeFlags = [ "-DVGL_SYSTEMFLTK=1" "-DTJPEG_LIBRARY=${libjpeg_turbo.out}/lib/libturbojpeg.so" ];
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [ libjpeg_turbo libGL libGLU fltk libX11 libXv libXtst ];
+
+  enableParallelBuilding = true;
+
+  meta = with stdenv.lib; {
+    homepage = http://www.virtualgl.org/;
+    description = "X11 GL rendering in a remote computer with full 3D hw acceleration";
+    license = licenses.wxWindows;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ abbradar ];
+  };
+}