1 files changed, 43 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/servers/pr-tracker/default.nix b/nixpkgs/pkgs/servers/pr-tracker/default.nix
new file mode 100644
index 000000000000..a1d0d4ecc59f
--- /dev/null
+++ b/nixpkgs/pkgs/servers/pr-tracker/default.nix
@@ -0,0 +1,43 @@
+{ rustPlatform
+, lib
+, fetchzip
+, gitMinimal
+, openssl
+, makeWrapper
+, pkg-config
+, systemd
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "pr-tracker";
+  version = "1.4.0";
+
+  src = fetchzip {
+    url = "https://git.qyliss.net/pr-tracker/snapshot/pr-tracker-${version}.tar.xz";
+    hash = "sha256-pCT74nAbtULvyS2BQ+XQU3LzF/q05wLaEeSa9j3DoAo=";
+  };
+
+  cargoHash = "sha256-WFI7eyr7fdQ6ePXQ+n/VrtPQ2eMZpVR68nGRBBlq3JU=";
+
+  nativeBuildInputs = [ makeWrapper pkg-config ];
+  buildInputs = [ openssl systemd ];
+
+  postInstall = ''
+    wrapProgram $out/bin/pr-tracker \
+        --prefix PATH : ${lib.makeBinPath [ gitMinimal ]}
+  '';
+
+  meta = with lib; {
+    changelog = "https://git.qyliss.net/pr-tracker/plain/NEWS?h=${version}";
+    description = "Nixpkgs pull request channel tracker";
+    longDescription = ''
+      A web server that displays the path a Nixpkgs pull request will take
+      through the various release channels.
+    '';
+    platforms = platforms.linux;
+    homepage = "https://git.qyliss.net/pr-tracker";
+    license = licenses.agpl3Plus;
+    maintainers = with maintainers; [ qyliss sumnerevans ];
+    mainProgram = "pr-tracker";
+  };
+}