2 files changed, 159 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/servers/meteor/default.nix b/nixpkgs/pkgs/servers/meteor/default.nix
new file mode 100644
index 000000000000..0ce2189568cb
--- /dev/null
+++ b/nixpkgs/pkgs/servers/meteor/default.nix
@@ -0,0 +1,103 @@
+{ stdenv, lib, fetchurl, zlib, curl, xz, patchelf, runtimeShell }:
+
+let
+  version = "2.7.3";
+
+  inherit (stdenv.hostPlatform) system;
+
+  srcs = {
+    x86_64-linux = fetchurl {
+      url = "https://static-meteor.netdna-ssl.com/packages-bootstrap/${version}/meteor-bootstrap-os.linux.x86_64.tar.gz";
+      sha256 = "sha256-ovsE7jUJIKf96WEoITXECUlPo+o1tEKvHzCc7Xgj614=";
+    };
+    x86_64-darwin = fetchurl {
+      url = "https://static-meteor.netdna-ssl.com/packages-bootstrap/${version}/meteor-bootstrap-os.osx.x86_64.tar.gz";
+      sha256 = "11206dbda50a680fdab7044def7ea68ea8f4a9bca948ca56df91fe1392b2ac16";
+    };
+  };
+in
+
+stdenv.mkDerivation {
+  inherit version;
+  pname = "meteor";
+  src = srcs.${system};
+
+  #dontStrip = true;
+
+  sourceRoot = ".meteor";
+
+  installPhase = ''
+    mkdir $out
+
+    cp -r packages $out
+    chmod -R +w $out/packages
+
+    cp -r package-metadata $out
+
+    devBundle=$(find $out/packages/meteor-tool -name dev_bundle)
+    ln -s $devBundle $out/dev_bundle
+
+    toolsDir=$(dirname $(find $out/packages -print | grep "meteor-tool/.*/tools/index.js$"))
+    ln -s $toolsDir $out/tools
+
+    # Meteor needs an initial package-metadata in $HOME/.meteor,
+    # otherwise it fails spectacularly.
+    mkdir -p $out/bin
+    cat << EOF > $out/bin/meteor
+    #!${runtimeShell}
+
+    if [[ ! -f \$HOME/.meteor/package-metadata/v2.0.1/packages.data.db ]]; then
+      mkdir -p \$HOME/.meteor/package-metadata/v2.0.1
+      cp $out/package-metadata/v2.0.1/packages.data.db "\$HOME/.meteor/package-metadata/v2.0.1"
+      chown "\$(whoami)" "\$HOME/.meteor/package-metadata/v2.0.1/packages.data.db"
+      chmod +w "\$HOME/.meteor/package-metadata/v2.0.1/packages.data.db"
+    fi
+
+    $out/dev_bundle/bin/node --no-wasm-code-gc \''${TOOL_NODE_FLAGS} $out/tools/index.js "\$@"
+    EOF
+    chmod +x $out/bin/meteor
+  '';
+
+  postFixup = lib.optionalString stdenv.isLinux ''
+    # Patch Meteor to dynamically fixup shebangs and ELF metadata where
+    # necessary.
+    pushd $out
+    patch -p1 < ${./main.patch}
+    popd
+    substituteInPlace $out/tools/cli/main.js \
+      --replace "@INTERPRETER@" "$(cat $NIX_CC/nix-support/dynamic-linker)" \
+      --replace "@RPATH@" "${lib.makeLibraryPath [ stdenv.cc.cc zlib curl xz ]}" \
+      --replace "@PATCHELF@" "${patchelf}/bin/patchelf"
+
+    # Patch node.
+    patchelf \
+      --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
+      --set-rpath "$(patchelf --print-rpath $out/dev_bundle/bin/node):${stdenv.cc.cc.lib}/lib" \
+      $out/dev_bundle/bin/node
+
+    # Patch mongo.
+    for p in $out/dev_bundle/mongodb/bin/mongo{,d}; do
+      patchelf \
+        --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
+        --set-rpath "$(patchelf --print-rpath $p):${lib.makeLibraryPath [ stdenv.cc.cc zlib curl xz ]}" \
+        $p
+    done
+
+    # Patch node dlls.
+    for p in $(find $out/packages -name '*.node'); do
+      patchelf \
+        --set-rpath "$(patchelf --print-rpath $p):${stdenv.cc.cc.lib}/lib" \
+        $p || true
+    done
+  '';
+
+  meta = with lib; {
+    description = "Complete open source platform for building web and mobile apps in pure JavaScript";
+    homepage = "https://www.meteor.com/";
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+    license = licenses.mit;
+    platforms = builtins.attrNames srcs;
+    maintainers = with maintainers; [ ];
+    mainProgram = "meteor";
+  };
+}
diff --git a/nixpkgs/pkgs/servers/meteor/main.patch b/nixpkgs/pkgs/servers/meteor/main.patch
new file mode 100644
index 000000000000..3282c91abac8
--- /dev/null
+++ b/nixpkgs/pkgs/servers/meteor/main.patch
@@ -0,0 +1,56 @@
+diff --git a/tools/cli/main.js b/tools/cli/main.js
+index 84f94bc..4fbda17 100644
+--- a/tools/cli/main.js
++++ b/tools/cli/main.js
+@@ -554,6 +554,44 @@
+     }).await());
+   } // Now exec; we're not coming back.
+ 
++  // BEGIN HACK
++  // patch shebang:
++  var fs = require('fs');
++  var path = require("path")
++  var Future = require("fibers/future")
++  var srcOld = fs.readFileSync(executable, 'utf8');
++  srcNew = srcOld.replace(/^#!\/bin\/bash/, '#!/bin/sh');
++  if (srcOld !== srcNew) {
++    fs.writeFileSync(executable, srcNew, 'utf8');
++  }
++  // patch elfs:
++  var dir = path.dirname(executable);
++  var interpreter = "@INTERPRETER@";
++  var rpath = "@RPATH@";
++  function spawnSync(/*...*/) {
++    var args = Array.prototype.slice.call(arguments);
++    var proc = require("child_process").spawn.apply(null, args);
++    var future = new Future();
++    proc.on('close', function (code) {
++      future.return();
++    });
++    return future.wait();
++  }
++  function patchelf(/*...*/) {
++    var pathParts = Array.prototype.slice.call(arguments);
++    var p = path.join.apply(null, [dir, "dev_bundle"].concat(pathParts));
++    spawnSync('@PATCHELF@', [
++      "--set-interpreter",
++      interpreter,
++      "--set-rpath",
++      rpath,
++      p
++    ], {stdio: 'inherit'});
++  }
++  patchelf("bin", "node");
++  patchelf("mongodb", "bin", "mongo");
++  patchelf("mongodb", "bin", "mongod");
++  // END HACK
+
+   require('kexec')(executable, newArgv);
+
+@@ -1485,4 +1523,4 @@
+
+   process.exit(ret);
+ }).run();
+-//# sourceMappingURL=main.js.map
+\ No newline at end of file
++//# sourceMappingURL=main.js.map