1 files changed, 40 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/servers/dgraph/default.nix b/nixpkgs/pkgs/servers/dgraph/default.nix
new file mode 100644
index 000000000000..de62b6e6a43b
--- /dev/null
+++ b/nixpkgs/pkgs/servers/dgraph/default.nix
@@ -0,0 +1,40 @@
+{ lib, buildGoModule, fetchFromGitHub, installShellFiles }:
+
+buildGoModule rec {
+  pname = "dgraph";
+  version = "20.03.3";
+
+  src = fetchFromGitHub {
+    owner = "dgraph-io";
+    repo = "dgraph";
+    rev = "v${version}";
+    sha256 = "0z2zc0mf7ndf3cpzi1js396s1yxpgfjaj9jacifsi8v6i6r0c6cz";
+  };
+
+  vendorSha256 = "1nz4yr3y4dr9l09hcsp8x3zhbww9kz0av1ax4192f5zxpw1q275s";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  # see licensing
+  buildPhase = ''
+    make oss BUILD_VERSION=${version}
+  '';
+
+  installPhase = ''
+    install dgraph/dgraph -Dt $out/bin
+
+    for shell in bash zsh; do
+      $out/bin/dgraph completion $shell > dgraph.$shell
+      installShellCompletion dgraph.$shell
+    done
+  '';
+
+  meta = with lib; {
+    homepage = "https://dgraph.io/";
+    description = "Fast, Distributed Graph DB";
+    maintainers = with maintainers; [ sigma ];
+    # Apache 2.0 because we use only build "oss"
+    license = licenses.asl20;
+    platforms = platforms.unix;
+  };
+}