3 files changed, 127 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/servers/calibre-web/db-migrations.patch b/nixpkgs/pkgs/servers/calibre-web/db-migrations.patch
new file mode 100644
index 000000000000..2e865db68da3
--- /dev/null
+++ b/nixpkgs/pkgs/servers/calibre-web/db-migrations.patch
@@ -0,0 +1,14 @@
+diff --git a/cps/__init__.py b/cps/__init__.py
+index 1ba1f778..fd5dc2f1 100644
+--- a/cps/__init__.py
++++ b/cps/__init__.py
+@@ -116,6 +116,9 @@ def create_app():
+     db.CalibreDB.setup_db(config.config_calibre_dir, cli_param.settings_path)
+     calibre_db.init_db()
+
++    if os.environ.get('__RUN_MIGRATIONS_AND_EXIT'):
++        sys.exit(0)
++
+     updater_thread.init_updater(config, web_server)
+     # Perform dry run of updater and exit afterwards
+     if cli_param.dry_run:
diff --git a/nixpkgs/pkgs/servers/calibre-web/default-logger.patch b/nixpkgs/pkgs/servers/calibre-web/default-logger.patch
new file mode 100644
index 000000000000..c5aecbd3d10c
--- /dev/null
+++ b/nixpkgs/pkgs/servers/calibre-web/default-logger.patch
@@ -0,0 +1,17 @@
+diff --git a/cps/logger.py b/cps/logger.py
+index b204de31..3206e2bf 100644
+--- a/cps/logger.py
++++ b/cps/logger.py
+@@ -32,10 +32,10 @@ ACCESS_FORMATTER_TORNADO = Formatter("[%(asctime)s] %(message)s")
+ 
+ FORMATTER           = Formatter("[%(asctime)s] %(levelname)5s {%(name)s:%(lineno)d} %(message)s")
+ DEFAULT_LOG_LEVEL   = logging.INFO
+-DEFAULT_LOG_FILE    = os.path.join(_CONFIG_DIR, "calibre-web.log")
+-DEFAULT_ACCESS_LOG  = os.path.join(_CONFIG_DIR, "access.log")
+ LOG_TO_STDERR       = '/dev/stderr'
+ LOG_TO_STDOUT       = '/dev/stdout'
++DEFAULT_LOG_FILE    = LOG_TO_STDOUT
++DEFAULT_ACCESS_LOG  = LOG_TO_STDOUT
+ 
+ logging.addLevelName(logging.WARNING, "WARN")
+ logging.addLevelName(logging.CRITICAL, "CRIT")
diff --git a/nixpkgs/pkgs/servers/calibre-web/default.nix b/nixpkgs/pkgs/servers/calibre-web/default.nix
new file mode 100644
index 000000000000..0d0afd185f41
--- /dev/null
+++ b/nixpkgs/pkgs/servers/calibre-web/default.nix
@@ -0,0 +1,96 @@
+{ lib
+, fetchFromGitHub
+, nixosTests
+, python3
+}:
+
+let
+  python = python3.override {
+    packageOverrides = self: super: {
+      sqlalchemy = super.sqlalchemy_1_4;
+    };
+  };
+in
+python.pkgs.buildPythonApplication rec {
+  pname = "calibre-web";
+  version = "0.6.21";
+
+  src = fetchFromGitHub {
+    owner = "janeczku";
+    repo = "calibre-web";
+    rev = version;
+    hash = "sha256-tRrOquetn3P2NmrXq7DQHRGP1sWnLR7bV2Lw0W/lUPQ=";
+  };
+
+  propagatedBuildInputs = with python.pkgs; [
+    apscheduler
+    advocate
+    chardet
+    flask-babel
+    flask-login
+    flask-principal
+    flask-wtf
+    flask-limiter
+    iso-639
+    jsonschema
+    lxml
+    pypdf
+    requests
+    sqlalchemy
+    tornado
+    unidecode
+    wand
+    werkzeug
+  ];
+
+  patches = [
+    # default-logger.patch switches default logger to /dev/stdout. Otherwise calibre-web tries to open a file relative
+    # to its location, which can't be done as the store is read-only. Log file location can later be configured using UI
+    # if needed.
+    ./default-logger.patch
+    # DB migrations adds an env var __RUN_MIGRATIONS_ANDEXIT that, when set, instructs calibre-web to run DB migrations
+    # and exit. This is gonna be used to configure calibre-web declaratively, as most of its configuration parameters
+    # are stored in the DB.
+    ./db-migrations.patch
+  ];
+
+  # calibre-web doesn't follow setuptools directory structure. The following is taken from the script
+  # that calibre-web's maintainer is using to package it:
+  # https://github.com/OzzieIsaacs/calibre-web-test/blob/master/build/make_release.py
+  postPatch = ''
+    mkdir -p src/calibreweb
+    mv cps.py src/calibreweb/__init__.py
+    mv cps src/calibreweb
+
+    sed -i "/backports_abc/d" setup.cfg
+
+    substituteInPlace setup.cfg \
+      --replace "cps = calibreweb:main" "calibre-web = calibreweb:main" \
+      --replace "APScheduler>=3.6.3,<3.10.0" "APScheduler>=3.6.3" \
+      --replace "chardet>=3.0.0,<4.1.0" "chardet>=3.0.0,<6" \
+      --replace "Flask>=1.0.2,<2.1.0" "Flask>=1.0.2" \
+      --replace "Flask-Babel>=0.11.1,<3.1.0" "Flask-Babel>=0.11.1" \
+      --replace "Flask-Login>=0.3.2,<0.6.2" "Flask-Login>=0.3.2" \
+      --replace "flask-wtf>=0.14.2,<1.1.0" "flask-wtf>=0.14.2" \
+      --replace "lxml>=3.8.0,<4.9.0" "lxml>=3.8.0" \
+      --replace "tornado>=4.1,<6.2" "tornado>=4.1,<7" \
+      --replace "PyPDF>=3.0.0,<3.6.0" "PyPDF>=3.0.0" \
+      --replace "requests>=2.11.1,<2.29.0" "requests" \
+      --replace "unidecode>=0.04.19,<1.4.0" "unidecode>=0.04.19" \
+      --replace "werkzeug<2.1.0" ""
+  '';
+
+  # Upstream repo doesn't provide any tests.
+  doCheck = false;
+
+  passthru.tests.calibre-web = nixosTests.calibre-web;
+
+  meta = with lib; {
+    description = "Web app for browsing, reading and downloading eBooks stored in a Calibre database";
+    homepage = "https://github.com/janeczku/calibre-web";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ pborzenkov ];
+    platforms = platforms.all;
+    mainProgram = "calibre-web";
+  };
+}