1 files changed, 32 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/servers/adguardhome/default.nix b/nixpkgs/pkgs/servers/adguardhome/default.nix
new file mode 100644
index 000000000000..44940468dc81
--- /dev/null
+++ b/nixpkgs/pkgs/servers/adguardhome/default.nix
@@ -0,0 +1,32 @@
+{ lib, stdenv, fetchurl, fetchzip, nixosTests }:
+
+let
+  inherit (stdenv.hostPlatform) system;
+  sources = import ./bins.nix { inherit fetchurl fetchzip; };
+in
+
+stdenv.mkDerivation rec {
+  pname = "adguardhome";
+  version = "0.107.36";
+  src = sources.${system} or (throw "Source for ${pname} is not available for ${system}");
+
+  installPhase = ''
+    install -m755 -D ./AdGuardHome $out/bin/adguardhome
+  '';
+
+  passthru = {
+    updateScript = ./update.sh;
+    schema_version = 24;
+    tests.adguardhome = nixosTests.adguardhome;
+  };
+
+  meta = with lib; {
+    homepage = "https://github.com/AdguardTeam/AdGuardHome";
+    description = "Network-wide ads & trackers blocking DNS server";
+    platforms = builtins.attrNames sources;
+    maintainers = with maintainers; [ numkem iagoq rhoriguchi ];
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+    license = licenses.gpl3Only;
+    mainProgram = "adguardhome";
+  };
+}