1 files changed, 73 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/os-specific/linux/iwd/default.nix b/nixpkgs/pkgs/os-specific/linux/iwd/default.nix
new file mode 100644
index 000000000000..fc7eda0af88c
--- /dev/null
+++ b/nixpkgs/pkgs/os-specific/linux/iwd/default.nix
@@ -0,0 +1,73 @@
+{ stdenv, fetchgit, autoreconfHook, pkgconfig, coreutils, readline, python3Packages }:
+
+let
+  ell = fetchgit {
+     url = https://git.kernel.org/pub/scm/libs/ell/ell.git;
+     rev = "0.17";
+     sha256 = "0yk1qmvpy61qp82bb0w55n062jqzlkzbz0b1v5k763j98czz9rvz";
+  };
+in stdenv.mkDerivation rec {
+  name = "iwd-${version}";
+  version = "0.14";
+
+  src = fetchgit {
+    url = https://git.kernel.org/pub/scm/network/wireless/iwd.git;
+    rev = version;
+    sha256 = "08ijlnwvj1w354gbv3hdnm3l4iy24qzq4bq5a9z0wynysasw09lv";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkgconfig
+    python3Packages.wrapPython
+  ];
+
+  buildInputs = [
+    readline
+    python3Packages.python
+  ];
+
+  pythonPath = [
+    python3Packages.dbus-python
+    python3Packages.pygobject3
+  ];
+
+  configureFlags = [
+    "--with-dbus-datadir=${placeholder "out"}/etc/"
+    "--with-dbus-busdir=${placeholder "out"}/share/dbus-1/system-services/"
+    "--with-systemd-unitdir=${placeholder "out"}/lib/systemd/system/"
+    "--localstatedir=/var/"
+    "--enable-wired"
+  ];
+
+  postUnpack = ''
+    ln -s ${ell} ell
+    patchShebangs .
+  '';
+
+  postInstall = ''
+    cp -a test/* $out/bin/
+    mkdir -p $out/share
+    cp -a doc $out/share/
+    cp -a README AUTHORS TODO $out/share/doc/
+  '';
+
+  preFixup = ''
+    wrapPythonPrograms
+  '';
+
+  postFixup = ''
+    substituteInPlace $out/share/dbus-1/system-services/net.connman.ead.service \
+                      --replace /bin/false ${coreutils}/bin/false
+    substituteInPlace $out/share/dbus-1/system-services/net.connman.iwd.service \
+                      --replace /bin/false ${coreutils}/bin/false
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = https://git.kernel.org/pub/scm/network/wireless/iwd.git;
+    description = "Wireless daemon for Linux";
+    license = licenses.lgpl21;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.mic92 ];
+  };
+}