1 files changed, 40 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/games/papermc/default.nix b/nixpkgs/pkgs/games/papermc/default.nix
new file mode 100644
index 000000000000..930b4462a7bd
--- /dev/null
+++ b/nixpkgs/pkgs/games/papermc/default.nix
@@ -0,0 +1,40 @@
+{ lib, stdenv, fetchurl, bash, jre }:
+
+stdenv.mkDerivation rec {
+  pname = "papermc";
+  version = "1.19.3.375";
+
+  jar = let
+    mcVersion = lib.versions.pad 3 version;
+    buildNum = builtins.elemAt (lib.versions.splitVersion version) 3;
+  in fetchurl {
+    url = "https://papermc.io/api/v2/projects/paper/versions/${mcVersion}/builds/${buildNum}/downloads/paper-${mcVersion}-${buildNum}.jar";
+    sha256 = "sha256-NAl4+mCkO6xQQpIx2pd9tYX2N8VQa+2dmFwyBNbDa10=";
+  };
+
+  preferLocalBuild = true;
+
+  dontUnpack = true;
+  dontConfigure = true;
+
+  buildPhase = ''
+    cat > minecraft-server << EOF
+    #!${bash}/bin/sh
+    exec ${jre}/bin/java \$@ -jar $out/share/papermc/papermc.jar nogui
+  '';
+
+  installPhase = ''
+    install -Dm444 ${jar} $out/share/papermc/papermc.jar
+    install -Dm555 -t $out/bin minecraft-server
+  '';
+
+  meta = {
+    description = "High-performance Minecraft Server";
+    homepage    = "https://papermc.io/";
+    sourceProvenance = with lib.sourceTypes; [ binaryBytecode ];
+    license     = lib.licenses.gpl3Only;
+    platforms   = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ aaronjanse neonfuz ];
+    mainProgram = "minecraft-server";
+  };
+}