1 files changed, 67 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/games/blightmud/default.nix b/nixpkgs/pkgs/games/blightmud/default.nix
new file mode 100644
index 000000000000..d536aa7b8ea6
--- /dev/null
+++ b/nixpkgs/pkgs/games/blightmud/default.nix
@@ -0,0 +1,67 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, rustPlatform
+, pkg-config
+, alsa-lib
+, openssl
+, withTTS ? false
+, speechd
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "blightmud";
+  version = "5.2.0";
+
+  src = fetchFromGitHub {
+    owner = pname;
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "sha256-sLqkDuohCgHJTMte1WIa2Yu43oWXVvnIpeiDBoQpKY8=";
+  };
+
+  cargoHash = "sha256-ffADKoMysYY2vwX3asHnjR2EiND4RJsf/W334PWvkGs=";
+
+  buildFeatures = lib.optional withTTS "tts";
+
+  nativeBuildInputs = [ pkg-config rustPlatform.bindgenHook ];
+
+  buildInputs = [ alsa-lib openssl ] ++ lib.optionals withTTS [ speechd ];
+
+  checkFlags =
+    let
+      # Most of Blightmud's unit tests pass without trouble in the isolated
+      # Nixpkgs build env. The following tests need to be skipped.
+      skipList = [
+        "test_connect"
+        "test_gmcp_negotiation"
+        "test_ttype_negotiation"
+        "test_reconnect"
+        "test_is_connected"
+        "test_mud"
+        "test_server"
+        "test_lua_script"
+        "timer_test"
+        "validate_assertion_fail"
+      ];
+      skipFlag = test: "--skip " + test;
+    in
+    builtins.concatStringsSep " " (builtins.map skipFlag skipList);
+
+  meta = with lib; {
+    description = "A terminal MUD client written in Rust";
+    longDescription = ''
+      Blightmud is a terminal client for connecting to Multi User Dungeon (MUD)
+      games. It is written in Rust and supports TLS, GMCP, MSDP, MCCP2, tab
+      completion, text searching and a split view for scrolling. Blightmud can
+      be customized with Lua scripting for aliases, triggers, timers, customized
+      status bars, and more. Blightmud supports several accessibility features
+      including an optional built-in text-to-speech engine and a screen reader
+      friendly mode.
+    '';
+    homepage = "https://github.com/Blightmud/Blightmud";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ cpu ];
+    platforms = platforms.linux;
+  };
+}