1 files changed, 43 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/tools/schemacrawler/default.nix b/nixpkgs/pkgs/development/tools/schemacrawler/default.nix
new file mode 100644
index 000000000000..0d4ffad56977
--- /dev/null
+++ b/nixpkgs/pkgs/development/tools/schemacrawler/default.nix
@@ -0,0 +1,43 @@
+{ lib
+, stdenv
+, fetchzip
+, jre
+, makeWrapper
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "schemacrawler";
+  version = "16.21.2";
+
+  src = fetchzip {
+    url = "https://github.com/schemacrawler/SchemaCrawler/releases/download/v${finalAttrs.version}/schemacrawler-${finalAttrs.version}-bin.zip";
+    hash = "sha256-M8kHJOkbxJGpZWOZ1asGYPM76ZWSpkaYIAfWsaisXLs=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    cp -r {config,lib} $out/
+
+    makeWrapper ${jre}/bin/java $out/bin/schemacrawler \
+      --add-flags "-cp $out/lib/*:$out/config" \
+      --add-flags schemacrawler.Main
+
+    runHook postInstall
+  '';
+
+  preferLocalBuild = true;
+
+  meta = with lib; {
+    description = "Database schema discovery and comprehension tool";
+    mainProgram = "schemacrawler";
+    homepage = "https://www.schemacrawler.com/";
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    license = with licenses; [ epl10 gpl3Only lgpl3Only ];
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ elohmeier ];
+  };
+})