1 files changed, 51 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/tools/continuous-integration/gitlab-runner/default.nix b/nixpkgs/pkgs/development/tools/continuous-integration/gitlab-runner/default.nix
new file mode 100644
index 000000000000..aa262fd54952
--- /dev/null
+++ b/nixpkgs/pkgs/development/tools/continuous-integration/gitlab-runner/default.nix
@@ -0,0 +1,51 @@
+{ lib, buildGoPackage, fetchFromGitLab, fetchurl }:
+
+let
+  version = "11.9.0";
+  # Gitlab runner embeds some docker images these are prebuilt for arm and x86_64
+  docker_x86_64 = fetchurl {
+    url = "https://gitlab-runner-downloads.s3.amazonaws.com/v${version}/helper-images/prebuilt-x86_64.tar.xz";
+    sha256 = "1la4pkf8xp5h75dlvb6w7ijczrnci3bmbl77h3y4jicz555jjir3";
+  };
+
+  docker_arm = fetchurl {
+    url = "https://gitlab-runner-downloads.s3.amazonaws.com/v${version}/helper-images/prebuilt-arm.tar.xz";
+    sha256 = "1axn34aqa17yk2c2vy73fb8ab3nc3021dzj0vk95qificlmj3par";
+  };
+in
+buildGoPackage rec {
+  inherit version;
+  name = "gitlab-runner-${version}";
+  goPackagePath = "gitlab.com/gitlab-org/gitlab-runner";
+  commonPackagePath = "${goPackagePath}/common";
+  buildFlagsArray = ''
+    -ldflags=
+      -X ${commonPackagePath}.NAME=gitlab-runner
+      -X ${commonPackagePath}.VERSION=${version}
+      -X ${commonPackagePath}.REVISION=v${version}
+  '';
+
+  src = fetchFromGitLab {
+    owner = "gitlab-org";
+    repo = "gitlab-runner";
+    rev = "v${version}";
+    sha256 = "1b4r83glx0n3l060k33s397dw5dpajlxb880yzwsb11hvc6cs39h";
+  };
+
+  patches = [ ./fix-shell-path.patch ];
+
+  postInstall = ''
+    touch $bin/bin/hello
+    install -d $bin/bin/helper-images
+    ln -sf ${docker_x86_64} $bin/bin/helper-images/prebuilt-x86_64.tar.xz
+    ln -sf ${docker_arm} $bin/bin/helper-images/prebuilt-arm.tar.xz
+  '';
+
+  meta = with lib; {
+    description = "GitLab Runner the continuous integration executor of GitLab";
+    license = licenses.mit;
+    homepage = https://about.gitlab.com/gitlab-ci/;
+    platforms = platforms.unix ++ platforms.darwin;
+    maintainers = with maintainers; [ bachp zimbatm ];
+  };
+}