1 files changed, 42 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/python-modules/pyfakefs/default.nix b/nixpkgs/pkgs/development/python-modules/pyfakefs/default.nix
new file mode 100644
index 000000000000..4b128db82eac
--- /dev/null
+++ b/nixpkgs/pkgs/development/python-modules/pyfakefs/default.nix
@@ -0,0 +1,42 @@
+{ stdenv, buildPythonPackage, fetchPypi, python, pytest, glibcLocales }:
+
+buildPythonPackage rec {
+  version = "3.5.7";
+  pname = "pyfakefs";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "8969435f8e7ca10f60c22096b02b15ad3af143de7d3bb4d73507b812bcdd8e37";
+  };
+
+  postPatch = ''
+    # test doesn't work in sandbox
+    substituteInPlace pyfakefs/tests/fake_filesystem_test.py \
+      --replace "test_expand_root" "notest_expand_root"
+    substituteInPlace pyfakefs/tests/fake_os_test.py \
+      --replace "test_path_links_not_resolved" "notest_path_links_not_resolved" \
+      --replace "test_append_mode_tell_linux_windows" "notest_append_mode_tell_linux_windows"
+    substituteInPlace pyfakefs/tests/fake_filesystem_unittest_test.py \
+      --replace "test_copy_real_file" "notest_copy_real_file"
+  '' + (stdenv.lib.optionalString stdenv.isDarwin ''
+    # this test fails on darwin due to case-insensitive file system
+    substituteInPlace pyfakefs/tests/fake_os_test.py \
+      --replace "test_rename_dir_to_existing_dir" "notest_rename_dir_to_existing_dir"
+  '');
+
+  checkInputs = [ pytest glibcLocales ];
+
+  checkPhase = ''
+    export LC_ALL=en_US.UTF-8
+    ${python.interpreter} -m pyfakefs.tests.all_tests
+    ${python.interpreter} -m pyfakefs.tests.all_tests_without_extra_packages
+    ${python.interpreter} -m pytest pyfakefs/tests/pytest/pytest_plugin_test.py
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Fake file system that mocks the Python file system modules";
+    license     = licenses.asl20;
+    homepage    = http://pyfakefs.org/;
+    maintainers = with maintainers; [ gebner ];
+  };
+}