1 files changed, 71 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/python-modules/cassandra-driver/default.nix b/nixpkgs/pkgs/development/python-modules/cassandra-driver/default.nix
new file mode 100644
index 000000000000..a40238412c6d
--- /dev/null
+++ b/nixpkgs/pkgs/development/python-modules/cassandra-driver/default.nix
@@ -0,0 +1,71 @@
+{ stdenv
+, libev
+, buildPythonPackage
+, fetchPypi
+, pkgs
+, cython
+, futures
+, six
+, python
+, scales
+, eventlet
+, twisted
+, mock
+, gevent
+, nose
+, pytz
+, pyyaml
+, sure
+, pythonOlder
+}:
+
+buildPythonPackage rec {
+  pname = "cassandra-driver";
+  version = "3.17.0";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "1z49z6f9rj9kp1v03s1hs1rg8cj49rh0yk0fc2qi57w7slgy2hkd";
+  };
+
+  buildInputs = [
+    libev
+  ];
+
+  nativeBuildInputs = [
+    # NOTE: next version will work with cython 0.29
+    # Requires 'Cython!=0.25,<0.29,>=0.20'
+    (cython.overridePythonAttrs(old: rec {
+      pname = "Cython";
+      version = "0.28.3";
+      src = fetchPypi {
+        inherit pname version;
+        sha256 = "1aae6d6e9858888144cea147eb5e677830f45faaff3d305d77378c3cba55f526";
+      };
+    }))
+  ];
+
+  propagatedBuildInputs = [ six ]
+    ++ stdenv.lib.optionals (pythonOlder "3.4") [ futures ];
+
+  postPatch = ''
+    sed -i "s/<=1.0.1//" setup.py
+  '';
+
+  checkPhase = ''
+    ${python.interpreter} setup.py gevent_nosetests
+    ${python.interpreter} setup.py eventlet_nosetests
+  '';
+
+  checkInputs = [ scales eventlet twisted mock gevent nose pytz pyyaml sure ];
+
+  # Could not get tests running
+  doCheck = false;
+
+  meta = with stdenv.lib; {
+    homepage = http://datastax.github.io/python-driver/;
+    description = "A Python client driver for Apache Cassandra";
+    license = licenses.asl20;
+  };
+
+}