3 files changed, 120 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/vtk/9.x.nix b/nixpkgs/pkgs/development/libraries/vtk/9.x.nix
new file mode 100644
index 000000000000..3734c20f0e05
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/vtk/9.x.nix
@@ -0,0 +1,5 @@
+import ./generic.nix {
+  majorVersion = "9.2";
+  minorVersion = "6";
+  sourceSha256 = "sha256-BvyNScTlb0mMQPyzilY+2NTsMTWNAQHomI8LtNU53RI=";
+}
diff --git a/nixpkgs/pkgs/development/libraries/vtk/generic.nix b/nixpkgs/pkgs/development/libraries/vtk/generic.nix
new file mode 100644
index 000000000000..02309b275bdc
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/vtk/generic.nix
@@ -0,0 +1,110 @@
+{ majorVersion, minorVersion, sourceSha256, patchesToFetch ? [] }:
+{ stdenv, lib, fetchurl, cmake, libGLU, libGL, libX11, xorgproto, libXt, libpng, libtiff
+, fetchpatch
+, enableQt ? false, qtx11extras, qttools, qtdeclarative, qtEnv
+, enablePython ? false, python ? throw "vtk: Python support requested, but no python interpreter was given."
+# Darwin support
+, AGL, Cocoa, CoreServices, DiskArbitration, IOKit, CFNetwork, Security, GLUT, OpenGL
+, ApplicationServices, CoreText, IOSurface, ImageIO, xpc, libobjc
+}:
+
+let
+  inherit (lib) optionalString optionals optional;
+
+  version = "${majorVersion}.${minorVersion}";
+  pythonMajor = lib.substring 0 1 python.pythonVersion;
+
+in stdenv.mkDerivation {
+  pname = "vtk${optionalString enableQt "-qvtk"}";
+  inherit version;
+
+  src = fetchurl {
+    url = "https://www.vtk.org/files/release/${majorVersion}/VTK-${version}.tar.gz";
+    sha256 = sourceSha256;
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [ libpng libtiff ]
+    ++ optionals enableQt [ (qtEnv "qvtk-qt-env" [ qtx11extras qttools qtdeclarative ]) ]
+    ++ optionals stdenv.isLinux [
+      libGLU
+      xorgproto
+      libXt
+    ] ++ optionals stdenv.isDarwin [
+      xpc
+      AGL
+      Cocoa
+      CoreServices
+      DiskArbitration
+      IOKit
+      CFNetwork
+      Security
+      ApplicationServices
+      CoreText
+      IOSurface
+      ImageIO
+      OpenGL
+      GLUT
+    ] ++ optionals enablePython [
+      python
+    ];
+  propagatedBuildInputs = optionals stdenv.isDarwin [ libobjc ]
+    ++ optionals stdenv.isLinux [ libX11 libGL ];
+    # see https://github.com/NixOS/nixpkgs/pull/178367#issuecomment-1238827254
+
+  patches = map fetchpatch patchesToFetch;
+
+  dontWrapQtApps = true;
+
+  # Shared libraries don't work, because of rpath troubles with the current
+  # nixpkgs cmake approach. It wants to call a binary at build time, just
+  # built and requiring one of the shared objects.
+  # At least, we use -fPIC for other packages to be able to use this in shared
+  # objects.
+  cmakeFlags = [
+    "-DCMAKE_C_FLAGS=-fPIC"
+    "-DCMAKE_CXX_FLAGS=-fPIC"
+    "-DVTK_MODULE_USE_EXTERNAL_vtkpng=ON"
+    "-DVTK_MODULE_USE_EXTERNAL_vtktiff=1"
+  ] ++ lib.optionals (!stdenv.isDarwin) [
+    "-DOPENGL_INCLUDE_DIR=${libGL}/include"
+  ] ++ [
+    "-DCMAKE_INSTALL_LIBDIR=lib"
+    "-DCMAKE_INSTALL_INCLUDEDIR=include"
+    "-DCMAKE_INSTALL_BINDIR=bin"
+    "-DVTK_VERSIONED_INSTALL=OFF"
+  ] ++ optionals enableQt [
+    "-DVTK_GROUP_ENABLE_Qt:STRING=YES"
+  ]
+    ++ optionals stdenv.isDarwin [ "-DOPENGL_INCLUDE_DIR=${OpenGL}/Library/Frameworks" ]
+    ++ optionals enablePython [
+      "-DVTK_WRAP_PYTHON:BOOL=ON"
+      "-DVTK_PYTHON_VERSION:STRING=${pythonMajor}"
+    ];
+
+  env = lib.optionalAttrs stdenv.cc.isClang {
+    NIX_CFLAGS_COMPILE = "-Wno-error=incompatible-function-pointer-types";
+  };
+
+  postPatch = optionalString stdenv.isDarwin ''
+    sed -i 's|COMMAND vtkHashSource|COMMAND "DYLD_LIBRARY_PATH=''${VTK_BINARY_DIR}/lib" ''${VTK_BINARY_DIR}/bin/vtkHashSource-${majorVersion}|' ./Parallel/Core/CMakeLists.txt
+    sed -i 's/fprintf(output, shift)/fprintf(output, "%s", shift)/' ./ThirdParty/libxml2/vtklibxml2/xmlschemas.c
+    sed -i 's/fprintf(output, shift)/fprintf(output, "%s", shift)/g' ./ThirdParty/libxml2/vtklibxml2/xpath.c
+  '';
+
+  postInstall = optionalString enablePython ''
+    substitute \
+      ${./vtk.egg-info} \
+      $out/${python.sitePackages}/vtk-${version}.egg-info \
+      --subst-var-by VTK_VER "${version}"
+  '';
+
+  meta = with lib; {
+    description = "Open source libraries for 3D computer graphics, image processing and visualization";
+    homepage = "https://www.vtk.org/";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ knedlsepp tfmoraes lheckemann ];
+    platforms = with platforms; unix;
+  };
+}
diff --git a/nixpkgs/pkgs/development/libraries/vtk/vtk.egg-info b/nixpkgs/pkgs/development/libraries/vtk/vtk.egg-info
new file mode 100644
index 000000000000..c932fce54070
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/vtk/vtk.egg-info
@@ -0,0 +1,5 @@
+Metadata-Version: 2.1
+Name: vtk
+Version: @VTK_VER@
+Summary: VTK is an open-source toolkit for 3D computer graphics, image processing, and visualization
+Platform: UNKNOWN