2 files changed, 94 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/vapoursynth/default.nix b/nixpkgs/pkgs/development/libraries/vapoursynth/default.nix
new file mode 100644
index 000000000000..53d70f4d369d
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/vapoursynth/default.nix
@@ -0,0 +1,53 @@
+{ stdenv, fetchFromGitHub, pkgconfig, autoreconfHook, makeWrapper
+, zimg, libass, python3, libiconv
+, ApplicationServices, nasm
+, ocrSupport ?  false, tesseract ? null
+, imwriSupport? true,  imagemagick7 ? null
+}:
+
+assert ocrSupport   -> tesseract != null;
+assert imwriSupport -> imagemagick7 != null;
+
+with stdenv.lib;
+
+stdenv.mkDerivation rec {
+  pname = "vapoursynth";
+  version = "R47.2";
+
+  src = fetchFromGitHub {
+    owner  = "vapoursynth";
+    repo   = "vapoursynth";
+    rev    = version;
+    sha256 = "004h0vvih7dlhkcz6l2786pf7s04qhiv0bii4gjx23cxyklglh9i";
+  };
+
+  nativeBuildInputs = [ pkgconfig autoreconfHook nasm makeWrapper ];
+  buildInputs = [
+    zimg libass
+    (python3.withPackages (ps: with ps; [ sphinx cython ]))
+  ] ++ optionals stdenv.isDarwin [ libiconv ApplicationServices ]
+    ++ optional ocrSupport   tesseract
+    ++ optional imwriSupport imagemagick7;
+
+  configureFlags = [
+    "--disable-static"
+    (optionalString (!ocrSupport)   "--disable-ocr")
+    (optionalString (!imwriSupport) "--disable-imwri")
+  ];
+
+  enableParallelBuilding = true;
+
+  postInstall = ''
+    wrapProgram $out/bin/vspipe \
+        --prefix PYTHONPATH : $out/${python3.sitePackages}
+  '';
+
+  meta = with stdenv.lib; {
+    description = "A video processing framework with the future in mind";
+    homepage    = http://www.vapoursynth.com/;
+    license     = licenses.lgpl21;
+    platforms   = platforms.x86_64;
+    maintainers = with maintainers; [ rnhmjoj tadeokondrak ];
+  };
+
+}
diff --git a/nixpkgs/pkgs/development/libraries/vapoursynth/editor.nix b/nixpkgs/pkgs/development/libraries/vapoursynth/editor.nix
new file mode 100644
index 000000000000..3853718c1541
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/vapoursynth/editor.nix
@@ -0,0 +1,41 @@
+{ stdenv, fetchFromBitbucket, makeWrapper
+, python3, vapoursynth
+, qmake, qtbase, qtwebsockets
+}:
+
+stdenv.mkDerivation rec {
+  pname = "vapoursynth-editor";
+  version = "R19";
+
+  src = fetchFromBitbucket {
+    owner = "mystery_keeper";
+    repo = pname;
+    rev = stdenv.lib.toLower version;
+    sha256 = "1zlaynkkvizf128ln50yvzz3b764f5a0yryp6993s9fkwa7djb6n";
+  };
+
+  nativeBuildInputs = [ qmake makeWrapper ];
+  buildInputs = [ qtbase vapoursynth qtwebsockets ];
+
+  preConfigure = "cd pro";
+
+  installPhase = ''
+    cd ../build/release*
+    mkdir -p $out/bin
+    for bin in vsedit{,-job-server{,-watcher}}; do
+        mv $bin $out/bin
+
+        wrapProgram $out/bin/$bin \
+            --prefix PYTHONPATH : ${vapoursynth}/${python3.sitePackages} \
+            --prefix LD_LIBRARY_PATH : ${vapoursynth}/lib
+    done
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Cross-platform editor for VapourSynth scripts";
+    homepage = "https://bitbucket.org/mystery_keeper/vapoursynth-editor";
+    license = licenses.mit;
+    maintainers = with maintainers; [ tadeokondrak ];
+    platforms = platforms.all;
+  };
+}