1 files changed, 78 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/raylib/default.nix b/nixpkgs/pkgs/development/libraries/raylib/default.nix
new file mode 100644
index 000000000000..bb59eb9d654c
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/raylib/default.nix
@@ -0,0 +1,78 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, cmake
+, fetchpatch
+, mesa
+, libGLU
+, glfw
+, libX11
+, libXi
+, libXcursor
+, libXrandr
+, libXinerama
+, alsaSupport ? stdenv.hostPlatform.isLinux
+, alsa-lib
+, pulseSupport ? stdenv.hostPlatform.isLinux
+, libpulseaudio
+, sharedLib ? true
+, includeEverything ? true
+, raylib-games
+, darwin
+}:
+let
+  inherit (darwin.apple_sdk.frameworks) Carbon Cocoa OpenGL;
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "raylib";
+  version = "5.0";
+
+  src = fetchFromGitHub {
+    owner = "raysan5";
+    repo = "raylib";
+    rev = finalAttrs.version;
+    hash = "sha256-gEstNs3huQ1uikVXOW4uoYnIDr5l8O9jgZRTX1mkRww=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [ glfw ]
+    ++ lib.optionals stdenv.isLinux [ mesa libXi libXcursor libXrandr libXinerama ]
+    ++ lib.optionals stdenv.isDarwin [ Carbon Cocoa ]
+    ++ lib.optional alsaSupport alsa-lib
+    ++ lib.optional pulseSupport libpulseaudio;
+
+  propagatedBuildInputs = lib.optionals stdenv.isLinux [ libGLU libX11 ]
+    ++ lib.optionals stdenv.isDarwin [ OpenGL ];
+
+  # https://github.com/raysan5/raylib/wiki/CMake-Build-Options
+  cmakeFlags = [
+    "-DUSE_EXTERNAL_GLFW=ON"
+    "-DBUILD_EXAMPLES=OFF"
+    "-DCUSTOMIZE_BUILD=1"
+  ] ++ lib.optional includeEverything "-DINCLUDE_EVERYTHING=ON"
+  ++ lib.optional sharedLib "-DBUILD_SHARED_LIBS=ON";
+
+  passthru.tests = [ raylib-games ];
+
+  patches = [
+    # Patch version in CMakeLists.txt to 5.0.0
+    # The library author doesn't use cmake, so when updating this package please
+    # check that the resulting library extension matches the version
+    # and remove/update this patch (resulting library name should match
+    # libraylib.so.${finalAttrs.version}
+    (fetchpatch {
+      url = "https://github.com/raysan5/raylib/commit/032cc497ca5aaca862dc926a93c2a45ed8017737.patch";
+      hash = "sha256-qsX5AwyQaGoRsbdszOO7tUF9dR+AkEFi4ebNkBVHNEY=";
+    })
+  ];
+
+  meta = with lib; {
+    description = "A simple and easy-to-use library to enjoy videogames programming";
+    homepage = "https://www.raylib.com/";
+    license = licenses.zlib;
+    maintainers = with maintainers; [ adamlwgriffiths ];
+    platforms = platforms.all;
+    changelog = "https://github.com/raysan5/raylib/blob/${finalAttrs.version}/CHANGELOG";
+  };
+})