3 files changed, 103 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/qwt/6.nix b/nixpkgs/pkgs/development/libraries/qwt/6.nix
new file mode 100644
index 000000000000..1f2518fc7380
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/qwt/6.nix
@@ -0,0 +1,31 @@
+{ lib, stdenv, fetchurl, qtbase, qtsvg, qttools, qmake }:
+
+stdenv.mkDerivation rec {
+  name = "qwt-6.1.6";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/qwt/${name}.tar.bz2";
+    sha256 = "sha256-mUYNMcEV7kEXsBddiF9HwsWQ14QgbwmBXcBY++Xt4fY=";
+  };
+
+  propagatedBuildInputs = [ qtbase qtsvg qttools ];
+  nativeBuildInputs = [ qmake ];
+
+  postPatch = ''
+    sed -e "s|QWT_INSTALL_PREFIX.*=.*|QWT_INSTALL_PREFIX = $out|g" -i qwtconfig.pri
+  '';
+
+  qmakeFlags = [ "-after doc.path=$out/share/doc/${name}" ];
+
+  dontWrapQtApps = true;
+
+  meta = with lib; {
+    description = "Qt widgets for technical applications";
+    homepage = "http://qwt.sourceforge.net/";
+    # LGPL 2.1 plus a few exceptions (more liberal)
+    license = lib.licenses.qwt;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.bjornfor ];
+    branch = "6";
+  };
+}
diff --git a/nixpkgs/pkgs/development/libraries/qwt/6_qt4.nix b/nixpkgs/pkgs/development/libraries/qwt/6_qt4.nix
new file mode 100644
index 000000000000..61903af93fac
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/qwt/6_qt4.nix
@@ -0,0 +1,41 @@
+{ lib, stdenv, fetchurl, qt4, qmake4Hook, AGL }:
+
+stdenv.mkDerivation rec {
+  name = "qwt-6.1.5";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/qwt/${name}.tar.bz2";
+    sha256 = "0hf0mpca248xlqn7xnzkfj8drf19gdyg5syzklvq8pibxiixwxj0";
+  };
+
+  buildInputs = [
+    qt4
+  ] ++ lib.optionals stdenv.isDarwin [ AGL ];
+
+  nativeBuildInputs = [ qmake4Hook ];
+
+  enableParallelBuilding = true;
+
+  postPatch = ''
+    sed -e "s|QWT_INSTALL_PREFIX.*=.*|QWT_INSTALL_PREFIX = $out|g" -i qwtconfig.pri
+  '';
+
+  # qwt.framework output includes a relative reference to itself, which breaks dependents
+  preFixup =
+    lib.optionalString stdenv.isDarwin ''
+      echo "Attempting to repair qwt"
+      install_name_tool -id "$out/lib/qwt.framework/Versions/6/qwt" "$out/lib/qwt.framework/Versions/6/qwt"
+    '';
+
+  qmakeFlags = [ "-after doc.path=$out/share/doc/${name}" ];
+
+  meta = with lib; {
+    description = "Qt widgets for technical applications";
+    homepage = "http://qwt.sourceforge.net/";
+    # LGPL 2.1 plus a few exceptions (more liberal)
+    license = lib.licenses.qwt;
+    platforms = platforms.linux ++ platforms.darwin;
+    maintainers = [ maintainers.bjornfor ];
+    branch = "6";
+  };
+}
diff --git a/nixpkgs/pkgs/development/libraries/qwt/default.nix b/nixpkgs/pkgs/development/libraries/qwt/default.nix
new file mode 100644
index 000000000000..e158fe348856
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/qwt/default.nix
@@ -0,0 +1,31 @@
+{ lib, stdenv, fetchurl, qt4, qmake4Hook }:
+
+stdenv.mkDerivation rec {
+  name = "qwt-5.2.3";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/qwt/${name}.tar.bz2";
+    sha256 = "1dqa096mm6n3bidfq2b67nmdsvsw4ndzzd1qhl6hn8skcwqazzip";
+  };
+
+  propagatedBuildInputs = [ qt4 ];
+  nativeBuildInputs = [ qmake4Hook ];
+
+  postPatch = ''
+    sed -e "s@\$\$\[QT_INSTALL_PLUGINS\]@$out/lib/qt4/plugins@" -i designer/designer.pro
+    sed -e "s|INSTALLBASE.*=.*|INSTALLBASE = $out|g" -i qwtconfig.pri
+  '';
+
+  preConfigure = ''
+    qmakeFlags="$qmakeFlags INSTALLBASE=$out -after doc.path=$out/share/doc/${name}"
+  '';
+
+  meta = with lib; {
+    description = "Qt widgets for technical applications";
+    homepage = "http://qwt.sourceforge.net/";
+    # LGPL 2.1 plus a few exceptions (more liberal)
+    license = lib.licenses.qwt;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.bjornfor ];
+  };
+}