2 files changed, 91 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/qgnomeplatform/default.nix b/nixpkgs/pkgs/development/libraries/qgnomeplatform/default.nix
new file mode 100644
index 000000000000..a82d048b32b2
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/qgnomeplatform/default.nix
@@ -0,0 +1,67 @@
+{ mkDerivation
+, lib
+, fetchFromGitHub
+, pkgconfig
+, gtk3
+, glib
+, qtbase
+, qmake
+, qtx11extras
+, pantheon
+, substituteAll
+, gsettings-desktop-schemas
+}:
+
+mkDerivation rec {
+  pname = "qgnomeplatform";
+  version = "0.6.1";
+
+  src = fetchFromGitHub {
+    owner = "FedoraQt";
+    repo = "QGnomePlatform";
+    rev = version;
+    sha256 = "1mwqg2zk0sfjq54vz2jjahbgi5sxw8rb71h6mgg459wp99mhlqi0";
+  };
+
+  patches = [
+    # Hardcode GSettings schema path to avoid crashes from missing schemas
+    (substituteAll {
+      src = ./hardcode-gsettings.patch;
+      gds_gsettings_path = glib.getSchemaPath gsettings-desktop-schemas;
+    })
+  ];
+
+  nativeBuildInputs = [
+    pkgconfig
+    qmake
+  ];
+
+  buildInputs = [
+    glib
+    gtk3
+    qtbase
+    qtx11extras
+  ];
+
+  postPatch = ''
+    # Fix plugin dir
+    substituteInPlace decoration/decoration.pro \
+      --replace "\$\$[QT_INSTALL_PLUGINS]" "$out/$qtPluginPrefix"
+    substituteInPlace theme/theme.pro \
+      --replace "\$\$[QT_INSTALL_PLUGINS]" "$out/$qtPluginPrefix"
+  '';
+
+  passthru = {
+    updateScript = pantheon.updateScript {
+      attrPath = pname;
+    };
+  };
+
+  meta = with lib; {
+    description = "QPlatformTheme for a better Qt application inclusion in GNOME";
+    homepage = "https://github.com/FedoraQt/QGnomePlatform";
+    license = licenses.lgpl21Plus;
+    maintainers = with maintainers; [ worldofpeace ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/nixpkgs/pkgs/development/libraries/qgnomeplatform/hardcode-gsettings.patch b/nixpkgs/pkgs/development/libraries/qgnomeplatform/hardcode-gsettings.patch
new file mode 100644
index 000000000000..9b342d7cf832
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/qgnomeplatform/hardcode-gsettings.patch
@@ -0,0 +1,24 @@
+diff --git a/common/gnomehintssettings.cpp b/common/gnomehintssettings.cpp
+index 9860e57..40fa6ec 100644
+--- a/common/gnomehintssettings.cpp
++++ b/common/gnomehintssettings.cpp
+@@ -80,9 +80,17 @@ void gtkMessageHandler(const gchar *log_domain,
+ GnomeHintsSettings::GnomeHintsSettings()
+     : QObject(0)
+     , m_usePortal(checkUsePortalSupport())
+-    , m_gnomeDesktopSettings(g_settings_new("org.gnome.desktop.wm.preferences"))
+-    , m_settings(g_settings_new("org.gnome.desktop.interface"))
+ {
++    g_autoptr(GSettingsSchemaSource) schemaSource = nullptr;
++    g_autoptr(GSettingsSchema) gnomeDesktopSchema = nullptr;
++    g_autoptr(GSettingsSchema) settingsSchema = nullptr;
++
++    schemaSource = g_settings_schema_source_new_from_directory("@gds_gsettings_path@", g_settings_schema_source_get_default(), true, nullptr);
++    gnomeDesktopSchema = g_settings_schema_source_lookup(schemaSource, "org.gnome.desktop.wm.preferences", false);
++    m_gnomeDesktopSettings = g_settings_new_full(gnomeDesktopSchema, nullptr, nullptr);
++    settingsSchema = g_settings_schema_source_lookup(schemaSource, "org.gnome.desktop.interface", false);
++    m_settings = g_settings_new_full(settingsSchema, nullptr, nullptr);
++
+     gtk_init(nullptr, nullptr);
+ 
+     // Set log handler to suppress false GtkDialog warnings