2 files changed, 48 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/nuspell/default.nix b/nixpkgs/pkgs/development/libraries/nuspell/default.nix
new file mode 100644
index 000000000000..c16305018d71
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/nuspell/default.nix
@@ -0,0 +1,35 @@
+{ lib, stdenv, fetchFromGitHub, cmake, pkg-config, icu, catch2, pandoc }:
+
+stdenv.mkDerivation rec {
+  pname = "nuspell";
+  version = "4.2.0";
+
+  src = fetchFromGitHub {
+    owner = "nuspell";
+    repo = "nuspell";
+    rev = "v${version}";
+    sha256 = "sha256-sQ3Q2+FOf2bXCKcgd6XvEb+QZzzDccs/4+CpJbEd1PQ=";
+  };
+
+  nativeBuildInputs = [ cmake pkg-config pandoc ];
+  buildInputs = [ icu ];
+
+  outputs = [ "out" "lib" "dev" "man" ];
+
+  postPatch = ''
+    rm -rf external/Catch2
+    ln -sf ${catch2.src} external/Catch2
+  '';
+
+  postInstall = ''
+    rm -rf $out/share/doc
+  '';
+
+  meta = with lib; {
+    description = "Free and open source C++ spell checking library";
+    homepage = "https://nuspell.github.io/";
+    platforms = platforms.all;
+    maintainers = with maintainers; [ fpletz ];
+    license = licenses.lgpl3Plus;
+  };
+}
diff --git a/nixpkgs/pkgs/development/libraries/nuspell/wrapper.nix b/nixpkgs/pkgs/development/libraries/nuspell/wrapper.nix
new file mode 100644
index 000000000000..4386542ff20e
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/nuspell/wrapper.nix
@@ -0,0 +1,13 @@
+{ stdenv, lib, nuspell, makeWrapper, dicts ? [] }:
+with lib;
+let
+  searchPath = makeSearchPath "share/hunspell" dicts;
+in
+stdenv.mkDerivation {
+  name = (appendToName "with-dicts" nuspell).name;
+  buildInputs = [ makeWrapper ];
+  buildCommand = ''
+    makeWrapper ${nuspell}/bin/nuspell $out/bin/nuspell --prefix DICPATH : ${searchPath}
+  '';
+  meta = removeAttrs nuspell.meta ["outputsToInstall"];
+}