3 files changed, 116 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/libva/1.0.0.nix b/nixpkgs/pkgs/development/libraries/libva/1.0.0.nix
new file mode 100644
index 000000000000..1debefed0ad9
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libva/1.0.0.nix
@@ -0,0 +1,37 @@
+{ stdenv, lib, fetchurl, libX11, pkgconfig, libXext, libdrm, libXfixes, wayland, libffi
+, libGL, mesa
+, minimal ? false, libva1-minimal
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libva";
+  version = "1.7.3";
+
+  src = fetchurl {
+    url = "https://www.freedesktop.org/software/vaapi/releases/libva/${pname}-${version}.tar.bz2";
+    sha256 = "1ndrf136rlw03xag7j1xpmf9015d1h0dpnv6v587jnh6k2a17g12";
+  };
+
+  outputs = [ "bin" "dev" "out" ];
+
+  nativeBuildInputs = [ pkgconfig ];
+
+  buildInputs = [ libdrm ]
+    ++ lib.optionals (!minimal) [ libva1-minimal libX11 libXext libXfixes wayland libffi libGL ];
+  # TODO: share libs between minimal and !minimal - perhaps just symlink them
+
+  configureFlags =
+    # Add FHS paths for non-NixOS applications.
+    [ "--with-drivers-path=${mesa.drivers.driverLink}/lib/dri:/usr/lib/dri:/usr/lib32/dri" ] ++
+    lib.optionals (!minimal) [ "--enable-glx" ];
+
+  installFlags = [ "dummy_drv_video_ladir=$(out)/lib/dri" ];
+
+  meta = with stdenv.lib; {
+    homepage = "http://www.freedesktop.org/wiki/Software/vaapi";
+    license = licenses.mit;
+    description = "VAAPI library: Video Acceleration API";
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ ];
+  };
+}
diff --git a/nixpkgs/pkgs/development/libraries/libva/default.nix b/nixpkgs/pkgs/development/libraries/libva/default.nix
new file mode 100644
index 000000000000..7f690f0997b0
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libva/default.nix
@@ -0,0 +1,47 @@
+{ stdenv, lib, fetchFromGitHub, fetchpatch, meson, pkg-config, ninja, wayland
+, libdrm
+, minimal ? false, libva-minimal
+, libX11, libXext, libXfixes, libffi, libGL
+, mesa
+}:
+
+stdenv.mkDerivation rec {
+  name = "libva-${lib.optionalString minimal "minimal-"}${version}";
+  version = "2.8.0"; # Also update the hash for libva-utils!
+
+  # update libva-utils and vaapiIntel as well
+  src = fetchFromGitHub {
+    owner  = "intel";
+    repo   = "libva";
+    rev    = version;
+    sha256 = "190cq173jzp5rkrczi8gzbwa0y3xk253v4wd205a5ilfngm7srns";
+  };
+
+  outputs = [ "dev" "out" ];
+
+  nativeBuildInputs = [ meson pkg-config ninja wayland ];
+
+  buildInputs = [ libdrm ]
+    ++ lib.optionals (!minimal) [ libva-minimal libX11 libXext libXfixes wayland libffi libGL ];
+  # TODO: share libs between minimal and !minimal - perhaps just symlink them
+
+  mesonFlags = [
+    # Add FHS paths for non-NixOS applications:
+    "-Ddriverdir=${mesa.drivers.driverLink}/lib/dri:/usr/lib/dri:/usr/lib32/dri"
+  ];
+
+  meta = with stdenv.lib; {
+    description = "An implementation for VA-API (Video Acceleration API)";
+    longDescription = ''
+      VA-API is an open-source library and API specification, which provides
+      access to graphics hardware acceleration capabilities for video
+      processing. It consists of a main library (this package) and
+      driver-specific acceleration backends for each supported hardware vendor.
+    '';
+    homepage = "https://01.org/linuxmedia/vaapi";
+    changelog = "https://raw.githubusercontent.com/intel/libva/${version}/NEWS";
+    license = licenses.mit;
+    maintainers = with maintainers; [ primeos ];
+    platforms = platforms.unix;
+  };
+}
diff --git a/nixpkgs/pkgs/development/libraries/libva/utils.nix b/nixpkgs/pkgs/development/libraries/libva/utils.nix
new file mode 100644
index 000000000000..5b9f4cdd8aa3
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libva/utils.nix
@@ -0,0 +1,32 @@
+{ stdenv, fetchFromGitHub, meson, ninja, pkg-config
+, libdrm, libva, libX11, libXext, libXfixes, wayland
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libva-utils";
+  inherit (libva) version;
+
+  src = fetchFromGitHub {
+    owner  = "intel";
+    repo   = "libva-utils";
+    rev    = version;
+    sha256 = "081hw2jnj64bpqwh9p41n5caqzm6dnj1ggnvvc5wrf4m2z1h2bjb";
+  };
+
+  nativeBuildInputs = [ meson ninja pkg-config ];
+
+  buildInputs = [ libdrm libva libX11 libXext libXfixes wayland ];
+
+  meta = with stdenv.lib; {
+    description = "A collection of utilities and examples for VA-API";
+    longDescription = ''
+      libva-utils is a collection of utilities and examples to exercise VA-API
+      in accordance with the libva project.
+    '';
+    homepage = "https://github.com/intel/libva-utils";
+    changelog = "https://raw.githubusercontent.com/intel/libva-utils/${version}/NEWS";
+    license = licenses.mit;
+    maintainers = with maintainers; [ primeos ];
+    platforms = platforms.unix;
+  };
+}