1 files changed, 43 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/liburing/default.nix b/nixpkgs/pkgs/development/libraries/liburing/default.nix
new file mode 100644
index 000000000000..386354b48e4d
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/liburing/default.nix
@@ -0,0 +1,43 @@
+{ stdenv, fetchgit
+, fetchpatch
+}:
+
+stdenv.mkDerivation rec {
+  pname = "liburing";
+  version = "0.2";
+
+  src = fetchgit {
+    url    = "http://git.kernel.dk/${pname}";
+    rev    = "refs/tags/${pname}-${version}";
+    sha256 = "0dxq7qjrwndgavrrc6y2wg54ia3y5wkmcyhpdk4l5pvh7hw6kpdz";
+  };
+
+  separateDebugInfo = true;
+  enableParallelBuilding = true;
+
+  outputs = [ "out" "lib" "dev" "man" ];
+
+  configurePhase = ''
+    ./configure \
+      --prefix=$out \
+      --includedir=$dev/include \
+      --libdir=$lib/lib \
+      --mandir=$man/share/man \
+  '';
+
+  # Copy the examples into $out.
+  postInstall = ''
+    mkdir -p $out/bin
+    cp ./examples/io_uring-cp examples/io_uring-test $out/bin
+    cp ./examples/link-cp $out/bin/io_uring-link-cp
+    cp ./examples/ucontext-cp $out/bin/io_uring-ucontext-cp
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Userspace library for the Linux io_uring API";
+    homepage    = https://git.kernel.dk/cgit/liburing/;
+    license     = licenses.lgpl21;
+    platforms   = platforms.linux;
+    maintainers = with maintainers; [ thoughtpolice ];
+  };
+}