1 files changed, 48 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/libqalculate/default.nix b/nixpkgs/pkgs/development/libraries/libqalculate/default.nix
new file mode 100644
index 000000000000..1b73af7037b6
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libqalculate/default.nix
@@ -0,0 +1,48 @@
+{ stdenv, fetchFromGitHub, mpfr, libxml2, intltool, pkgconfig, doxygen,
+  autoreconfHook, readline, libiconv, icu, curl, gnuplot, gettext }:
+
+stdenv.mkDerivation rec {
+  pname = "libqalculate";
+  version = "3.3.0";
+
+  src = fetchFromGitHub {
+    owner = "qalculate";
+    repo = "libqalculate";
+    rev = "v${version}";
+    sha256 = "1qgsngi9z1sr6pzgcq6kgng62arpc5xn2ai1ks69myzzmgwk8adp";
+  };
+
+  outputs = [ "out" "dev" "doc" ];
+
+  nativeBuildInputs = [ intltool pkgconfig autoreconfHook doxygen ];
+  buildInputs = [ curl gettext libiconv readline ];
+  propagatedBuildInputs = [ libxml2 mpfr icu ];
+  enableParallelBuilding = true;
+
+  preConfigure = ''
+    intltoolize -f
+  '';
+
+  patchPhase = ''
+    substituteInPlace libqalculate/Calculator.cc \
+      --replace 'commandline = "gnuplot"' 'commandline = "${gnuplot}/bin/gnuplot"' \
+      --replace '"gnuplot - ' '"${gnuplot}/bin/gnuplot - '
+  '' + stdenv.lib.optionalString stdenv.cc.isClang ''
+    substituteInPlace src/qalc.cc \
+      --replace 'printf(_("aborted"))' 'printf("%s", _("aborted"))'
+  '';
+
+  preBuild = ''
+    pushd docs/reference
+    doxygen Doxyfile
+    popd
+  '';
+
+  meta = with stdenv.lib; {
+    description = "An advanced calculator library";
+    homepage = http://qalculate.github.io;
+    maintainers = with maintainers; [ gebner ];
+    license = licenses.gpl2Plus;
+    platforms = platforms.all;
+  };
+}