2 files changed, 70 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/libpng/12.nix b/nixpkgs/pkgs/development/libraries/libpng/12.nix
new file mode 100644
index 000000000000..7199695ae74b
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libpng/12.nix
@@ -0,0 +1,31 @@
+{ stdenv, fetchurl, zlib }:
+
+assert stdenv.hostPlatform == stdenv.buildPlatform -> zlib != null;
+
+stdenv.mkDerivation rec {
+  name = "libpng-1.2.59";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/libpng/${name}.tar.xz";
+    sha256 = "1izw9ybm27llk8531w6h4jp4rk2rxy2s9vil16nwik5dp0amyqxl";
+  };
+
+  outputs = [ "out" "dev" "man" ];
+
+  propagatedBuildInputs = [ zlib ];
+
+  passthru = { inherit zlib; };
+
+  configureFlags = [ "--enable-static" ];
+
+  postInstall = ''mv "$out/bin" "$dev/bin"'';
+
+  meta = with stdenv.lib; {
+    description = "The official reference implementation for the PNG file format";
+    homepage = "http://www.libpng.org/pub/png/libpng.html";
+    license = licenses.libpng;
+    maintainers = [ ];
+    branch = "1.2";
+    platforms = platforms.unix;
+  };
+}
diff --git a/nixpkgs/pkgs/development/libraries/libpng/default.nix b/nixpkgs/pkgs/development/libraries/libpng/default.nix
new file mode 100644
index 000000000000..489007bc417d
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libpng/default.nix
@@ -0,0 +1,39 @@
+{ stdenv, fetchurl, zlib, apngSupport ? true }:
+
+assert zlib != null;
+
+let
+  patchVersion = "1.6.37";
+  patch_src = fetchurl {
+    url = "mirror://sourceforge/libpng-apng/libpng-${patchVersion}-apng.patch.gz";
+    sha256 = "1dh0250mw9b2hx7cdmnb2blk7ddl49n6vx8zz7jdmiwxy38v4fw2";
+  };
+  whenPatched = stdenv.lib.optionalString apngSupport;
+
+in stdenv.mkDerivation rec {
+  name = "libpng" + whenPatched "-apng" + "-${version}";
+  version = "1.6.37";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/libpng/libpng-${version}.tar.xz";
+    sha256 = "1jl8in381z0128vgxnvn33nln6hzckl7l7j9nqvkaf1m9n1p0pjh";
+  };
+  postPatch = whenPatched "gunzip < ${patch_src} | patch -Np1";
+
+  outputs = [ "out" "dev" "man" ];
+  outputBin = "dev";
+
+  propagatedBuildInputs = [ zlib ];
+
+  doCheck = true;
+
+  passthru = { inherit zlib; };
+
+  meta = with stdenv.lib; {
+    description = "The official reference implementation for the PNG file format" + whenPatched " with animation patch";
+    homepage = "http://www.libpng.org/pub/png/libpng.html";
+    license = licenses.libpng2;
+    platforms = platforms.all;
+    maintainers = [ maintainers.vcunat ];
+  };
+}