1 files changed, 38 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/libpcap/default.nix b/nixpkgs/pkgs/development/libraries/libpcap/default.nix
new file mode 100644
index 000000000000..b704878b1644
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libpcap/default.nix
@@ -0,0 +1,38 @@
+{ stdenv, fetchurl, flex, bison }:
+
+stdenv.mkDerivation rec {
+  pname = "libpcap";
+  version = "1.9.1";
+
+  src = fetchurl {
+    url = "https://www.tcpdump.org/release/${pname}-${version}.tar.gz";
+    sha256 = "153h1378diqyc27jjgz6gg5nxmb4ddk006d9xg69nqavgiikflk3";
+  };
+
+  nativeBuildInputs = [ flex bison ];
+
+  # We need to force the autodetection because detection doesn't
+  # work in pure build enviroments.
+  configureFlags = [
+    ("--with-pcap=" + {
+      linux = "linux";
+      darwin = "bpf";
+    }.${stdenv.hostPlatform.parsed.kernel.name})
+  ] ++ stdenv.lib.optionals (stdenv.hostPlatform == stdenv.buildPlatform) [
+    "ac_cv_linux_vers=2"
+  ];
+
+  dontStrip = stdenv.hostPlatform != stdenv.buildPlatform;
+
+  prePatch = stdenv.lib.optionalString stdenv.isDarwin ''
+    substituteInPlace configure --replace " -arch i386" ""
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = https://www.tcpdump.org;
+    description = "Packet Capture Library";
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ fpletz ];
+    license = licenses.bsd3;
+  };
+}