1 files changed, 56 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/libmtp/default.nix b/nixpkgs/pkgs/development/libraries/libmtp/default.nix
new file mode 100644
index 000000000000..c3c9c20e86fd
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libmtp/default.nix
@@ -0,0 +1,56 @@
+{ stdenv
+, autoconf
+, automake
+, fetchFromGitHub
+, gettext
+, lib
+, libiconv
+, libtool
+, libusb1
+, pkg-config
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libmtp";
+  version = "1.1.19";
+
+  src = fetchFromGitHub {
+    owner = "libmtp";
+    repo = "libmtp";
+    rev = "libmtp-${builtins.replaceStrings [ "." ] [ "-" ] version}";
+    sha256 = "sha256-o8JKoKVNpU/nHTDnKJpa8FlXt37fZnTf45WBTCxLyTs=";
+  };
+
+  outputs = [ "bin" "dev" "out" ];
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+    gettext
+    libtool
+    pkg-config
+  ];
+
+  buildInputs = [ libiconv ];
+
+  propagatedBuildInputs = [ libusb1 ];
+
+  preConfigure = "./autogen.sh";
+
+  configureFlags = [ "--with-udev=${placeholder "out"}/lib/udev" ];
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    homepage = "https://github.com/libmtp/libmtp";
+    description = "An implementation of Microsoft's Media Transfer Protocol";
+    longDescription = ''
+      libmtp is an implementation of Microsoft's Media Transfer Protocol (MTP)
+      in the form of a library suitable primarily for POSIX compliant operating
+      systems. We implement MTP Basic, the stuff proposed for standardization.
+    '';
+    platforms = platforms.unix;
+    license = licenses.lgpl21;
+    maintainers = with maintainers; [ lovesegfault ];
+  };
+}