1 files changed, 68 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/liblouis/default.nix b/nixpkgs/pkgs/development/libraries/liblouis/default.nix
new file mode 100644
index 000000000000..932edd20e9a6
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/liblouis/default.nix
@@ -0,0 +1,68 @@
+{ fetchFromGitHub
+, stdenv
+, autoreconfHook
+, pkgconfig
+, gettext
+, python3
+, texinfo
+, help2man
+, libyaml
+, perl
+}:
+
+stdenv.mkDerivation rec {
+  pname = "liblouis";
+  version = "3.12.0";
+
+  src = fetchFromGitHub {
+    owner = "liblouis";
+    repo = "liblouis";
+    rev = "v${version}";
+    sha256 = "0sw7iwb9158z7jslxj9jwh2vqbg0q8wq6fbmk9iz7sfkjqhi80hv";
+  };
+
+  outputs = [ "out" "dev" "man" "info" "doc" ];
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkgconfig
+    gettext
+    python3
+    # Docs, man, info
+    texinfo
+    help2man
+  ];
+
+  buildInputs = [
+    # lou_checkYaml
+    libyaml
+    # maketable.d
+    perl
+  ];
+
+  configureFlags = [
+    # Required by Python bindings
+    "--enable-ucs4"
+  ];
+
+  postPatch = ''
+    patchShebangs tests
+    substituteInPlace python/louis/__init__.py.in --replace "###LIBLOUIS_SONAME###" "$out/lib/liblouis.so"
+  '';
+
+  postInstall = ''
+    pushd python
+    python setup.py install --prefix="$out" --optimize=1
+    popd
+  '';
+
+  doCheck = true;
+
+  meta = with stdenv.lib; {
+    description = "Open-source braille translator and back-translator";
+    homepage = http://liblouis.org/;
+    license = licenses.lgpl21;
+    maintainers = with maintainers; [ jtojnar ];
+    platforms = platforms.unix;
+  };
+}