1 files changed, 66 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/libbluray/default.nix b/nixpkgs/pkgs/development/libraries/libbluray/default.nix
new file mode 100644
index 000000000000..3f90bb878adc
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libbluray/default.nix
@@ -0,0 +1,66 @@
+{ lib, stdenv, fetchurl, pkg-config, fontconfig, autoreconfHook, DiskArbitration
+, withJava ? false, jdk ? null, ant ? null
+, withAACS ? false, libaacs ? null
+, withBDplus ? false, libbdplus ? null
+, withMetadata ? true, libxml2 ? null
+, withFonts ? true, freetype ? null
+}:
+
+with lib;
+
+assert withJava -> jdk != null && ant != null;
+assert withAACS -> libaacs != null;
+assert withBDplus -> libbdplus != null;
+assert withMetadata -> libxml2 != null;
+assert withFonts -> freetype != null;
+
+# Info on how to use:
+# https://wiki.archlinux.org/index.php/BluRay
+
+stdenv.mkDerivation rec {
+  pname = "libbluray";
+  version  = "1.2.1";
+
+  src = fetchurl {
+    url = "http://get.videolan.org/libbluray/${version}/${pname}-${version}.tar.bz2";
+    sha256 = "1v1nmq631j0prih7pjl01ixhhwgrkjpxrjmmc342rsl8g4zyh8sj";
+  };
+
+  patches = optional withJava ./BDJ-JARFILE-path.patch;
+
+  nativeBuildInputs = [ pkg-config autoreconfHook ]
+                      ++ optionals withJava [ ant ]
+                      ;
+
+  buildInputs = [ fontconfig ]
+                ++ optional withJava jdk
+                ++ optional withMetadata libxml2
+                ++ optional withFonts freetype
+                ++ optional stdenv.isDarwin DiskArbitration
+                ;
+
+  propagatedBuildInputs = optional withAACS libaacs;
+
+  NIX_LDFLAGS = toString [
+    (optionalString withAACS   "-L${libaacs}/lib -laacs")
+    (optionalString withBDplus "-L${libbdplus}/lib -lbdplus")
+  ];
+
+  preConfigure = ''
+    ${optionalString withJava ''export JDK_HOME="${jdk.home}"''}
+  '';
+
+  configureFlags =  with lib;
+                    optional (! withJava) "--disable-bdjava-jar"
+                 ++ optional (! withMetadata) "--without-libxml2"
+                 ++ optional (! withFonts) "--without-freetype"
+                 ;
+
+  meta = with lib; {
+    homepage = "http://www.videolan.org/developers/libbluray.html";
+    description = "Library to access Blu-Ray disks for video playback";
+    license = licenses.lgpl21;
+    maintainers = with maintainers; [ abbradar ];
+    platforms = platforms.unix;
+  };
+}