2 files changed, 101 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/dee/0001-Fix-build-with-Vala-0.54.patch b/nixpkgs/pkgs/development/libraries/dee/0001-Fix-build-with-Vala-0.54.patch
new file mode 100644
index 000000000000..4ad8ec8ffc73
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/dee/0001-Fix-build-with-Vala-0.54.patch
@@ -0,0 +1,29 @@
+From 7bc49f8edd9a49d675ee5b163ab61b405e2d0258 Mon Sep 17 00:00:00 2001
+From: Jan Tojnar <jtojnar@gmail.com>
+Date: Thu, 7 Oct 2021 21:42:26 +0200
+Subject: [PATCH] Fix build with Vala 0.54
+
+Vala codegen now emits constructor methods so we need to skip @new
+so that we can use a custom one from our VAPI overrides.
+
+https://gitlab.gnome.org/GNOME/vala/-/commit/472765b90cd98c1a628975d20005c46352d665f8
+---
+ vapi/Dee-1.0.metadata | 2 ++
+ 1 file changed, 2 insertions(+)
+
+diff --git a/vapi/Dee-1.0.metadata b/vapi/Dee-1.0.metadata
+index 7e80de0..793ffd8 100644
+--- a/vapi/Dee-1.0.metadata
++++ b/vapi/Dee-1.0.metadata
+@@ -1,6 +1,8 @@
+ GListResultSet skip
+ GListResultSetClass skip
+ 
++Filter
++	.new skip
+ FilterModel
+ 	.filter unowned
+ Model
+-- 
+2.33.0
+
diff --git a/nixpkgs/pkgs/development/libraries/dee/default.nix b/nixpkgs/pkgs/development/libraries/dee/default.nix
new file mode 100644
index 000000000000..4a2199f450e6
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/dee/default.nix
@@ -0,0 +1,72 @@
+{ lib, stdenv
+, fetchgit
+, fetchpatch
+, pkg-config
+, glib
+, icu
+, gobject-introspection
+, dbus-glib
+, vala
+, python3
+, autoreconfHook
+}:
+
+stdenv.mkDerivation rec {
+  pname = "dee";
+  version = "unstable-2017-06-16";
+
+  outputs = [ "out" "dev" "py" ];
+
+  src = fetchgit {
+    url = "https://git.launchpad.net/ubuntu/+source/dee";
+    rev = "import/1.2.7+17.10.20170616-4ubuntu3";
+    sha256 = "09blrdj7229vscp4mkg0fabmcvc6jdpamvblrq86rbky7j2nnwlk";
+  };
+
+  patches = [
+    "${src}/debian/patches/gtkdocize.patch"
+    "${src}/debian/patches/strict-prototype.patch"
+    "${src}/debian/patches/vapi-skip-properties.patch"
+    ./0001-Fix-build-with-Vala-0.54.patch
+
+    # Fixes glib 2.62 deprecations
+    (fetchpatch {
+      name = "dee-1.2.7-deprecated-g_type_class_add_private.patch";
+      url = "https://src.fedoraproject.org/rpms/dee/raw/1a9a4ce3377074fabfca653ffe0287cd73aef82f/f/dee-1.2.7-deprecated-g_type_class_add_private.patch";
+      sha256 = "13nyprq7bb7lnzkcb7frcpzidbl836ycn5bvmwa2k0nhmj6ycbx5";
+    })
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    vala
+    autoreconfHook
+    gobject-introspection
+    python3
+  ];
+
+  buildInputs = [
+    glib
+    icu
+    dbus-glib
+  ];
+
+  configureFlags = [
+    "--disable-gtk-doc"
+    "--with-pygi-overrides-dir=${placeholder "py"}/${python3.sitePackages}/gi/overrides"
+  ];
+
+  # Compilation fails after a change in glib where
+  # g_string_free now returns a value
+  env.NIX_CFLAGS_COMPILE = "-Wno-error=unused-result";
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    description = "A library that uses DBus to provide objects allowing you to create Model-View-Controller type programs across DBus";
+    homepage = "https://launchpad.net/dee";
+    license = licenses.lgpl3;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ abbradar ];
+  };
+}