2 files changed, 70 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/appstream/default.nix b/nixpkgs/pkgs/development/libraries/appstream/default.nix
new file mode 100644
index 000000000000..62d72844386f
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/appstream/default.nix
@@ -0,0 +1,52 @@
+{ stdenv, fetchFromGitHub, meson, ninja, pkgconfig, gettext
+, xmlto, docbook_xsl, docbook_xml_dtd_45, libxslt
+, libstemmer, glib, xapian, libxml2, libyaml, gobject-introspection
+, pcre, itstool, gperf, vala
+}:
+
+stdenv.mkDerivation rec {
+  pname = "appstream";
+  version = "0.12.6";
+
+  src = fetchFromGitHub {
+    owner  = "ximion";
+    repo   = "appstream";
+    rev    = "APPSTREAM_${stdenv.lib.replaceStrings ["."] ["_"] version}";
+    sha256 = "0hbl26aw3g2hag7z4di9z59qz057qcywrxpnnmp86z7rngvjbqpx";
+  };
+
+  nativeBuildInputs = [
+    meson ninja pkgconfig gettext
+    libxslt xmlto docbook_xsl docbook_xml_dtd_45
+    gobject-introspection itstool vala
+  ];
+
+  buildInputs = [ libstemmer pcre glib xapian libxml2 libyaml gperf ];
+
+  prePatch = ''
+    substituteInPlace meson.build \
+      --replace /usr/include ${libstemmer}/include
+
+    substituteInPlace data/meson.build \
+      --replace /etc $out/etc
+  '';
+
+  mesonFlags = [
+    "-Dapidocs=false"
+    "-Ddocs=false"
+    "-Dvapi=true"
+  ];
+
+  meta = with stdenv.lib; {
+    description = "Software metadata handling library";
+    homepage    = https://www.freedesktop.org/wiki/Distributions/AppStream/;
+    longDescription = ''
+      AppStream is a cross-distro effort for building Software-Center applications
+      and enhancing metadata provided by software components.  It provides
+      specifications for meta-information which is shipped by upstream projects and
+      can be consumed by other software.
+    '';
+    license     = licenses.lgpl21Plus;
+    platforms   = platforms.linux;
+ };
+}
diff --git a/nixpkgs/pkgs/development/libraries/appstream/qt.nix b/nixpkgs/pkgs/development/libraries/appstream/qt.nix
new file mode 100644
index 000000000000..22f1566ad0ac
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/appstream/qt.nix
@@ -0,0 +1,18 @@
+{ stdenv, appstream, qtbase, qttools }:
+
+# TODO: look into using the libraries from the regular appstream derivation as we keep duplicates here
+
+stdenv.mkDerivation {
+  pname = "appstream-qt";
+  inherit (appstream) version src prePatch;
+
+  buildInputs = appstream.buildInputs ++ [ appstream qtbase ];
+
+  nativeBuildInputs = appstream.nativeBuildInputs ++ [ qttools ];
+
+  mesonFlags = appstream.mesonFlags ++ [ "-Dqt=true" ];
+
+  meta = appstream.meta // {
+    description = "Software metadata handling library - Qt";
+ };
+}